blob: 168902147e4df5dd0d09445122e68444247e3aa5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
|
# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Maintainer : Christian Rebischke <Chris.Rebischke@archlinux.org>
# Contributor: Daniel Micay <danielmicay@gmail.com>
# Contributor: <kang@insecure.ws>
# Contributor: Massimiliano Torromeo <massimiliano.torromeo@gmail.com>
# Contributor: Connor Behan <connor.behan@gmail.com>
# Contributor: henning mueller <henning@orgizm.net>
pkgbase=audit
pkgname=('audit' 'python-audit')
pkgver=2.8.5
pkgrel=7
pkgdesc='Userspace components of the audit framework'
url='https://people.redhat.com/sgrubb/audit'
arch=('x86_64')
makedepends=('krb5' 'libcap-ng' 'libldap' 'swig' 'linux-headers' 'python')
license=('GPL')
options=('emptydirs')
source=(${pkgbase}-${pkgver}.tar.gz::https://people.redhat.com/sgrubb/audit/${pkgbase}-${pkgver}.tar.gz)
sha512sums=('7d416aaa21c1a167f8e911ca82aecbaba804424f3243f505066c43ecc4a62a34feb2c27555e99d3268608404793dccca0f828c63670e3aa816016fb493f8174a')
prepare() {
cd ${pkgbase}-${pkgver}
sed 's|/var/run/auditd.pid|/run/auditd.pid|' -i init.d/auditd.service
}
build() {
cd ${pkgbase}-${pkgver}
./configure \
--prefix=/usr \
--sbindir=/usr/bin \
--sysconfdir=/etc \
--libexecdir=/usr/lib/audit \
--enable-gssapi-krb5=yes \
--enable-systemd=yes \
--with-libcap-ng=yes
make
[ -n "${SOURCE_DATE_EPOCH}" ] && touch -h -d @$SOURCE_DATE_EPOCH bindings/swig/python/audit.py
}
package_audit() {
depends=('krb5' 'libcap-ng')
provides=('libaudit.so' 'libauparse.so')
backup=(
etc/libaudit.conf
etc/audit/audit-stop.rules
etc/audit/auditd.conf
etc/audisp/audispd.conf
etc/audisp/audisp-remote.conf
etc/audisp/zos-remote.conf
etc/audisp/plugins.d/af_unix.conf
etc/audisp/plugins.d/audispd-zos-remote.conf
etc/audisp/plugins.d/au-remote.conf
etc/audisp/plugins.d/syslog.conf
)
cd ${pkgbase}-${pkgver}
make DESTDIR="${pkgdir}" INSTALL='install -p' install
cd "${pkgdir}"
install -d -m 0700 var/log/audit
rm -rf etc/rc.d \
etc/sysconfig \
usr/lib/audit \
usr/lib/python*
sed -ri 's|/sbin|/usr/bin|' \
etc/audit/*.conf \
etc/audisp/plugins.d/*.conf \
usr/lib/systemd/system/auditd.service
chmod 644 usr/lib/systemd/system/auditd.service
}
package_python-audit() {
depends=('python' 'audit')
pkgdesc+=' (python bindings)'
cd ${pkgbase}-${pkgver}
make -C bindings DESTDIR="${pkgdir}" INSTALL='install -p' install
}
# vim: ts=2 sw=2 et:
|
