blob: d2f7f52c35c1b0e9506c2c0ce8671227d9c11787 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# $Id: PKGBUILD 203041 2014-01-02 14:43:46Z dreisner $
# Maintainer: Dave Reisner <dreisner@archlinux.org>
# Contributor: Angel Velasquez <angvp@archlinux.org>
# Contributor: Eric Belanger <eric@archlinux.org>
# Contributor: Lucien Immink <l.immink@student.fnt.hvu.nl>
# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
pkgname=curl
pkgver=7.34.0
pkgrel=2
pkgdesc="An URL retrieval utility and library"
arch=('i686' 'x86_64')
url="http://curl.haxx.se"
license=('MIT')
depends=('ca-certificates' 'libssh2' 'openssl' 'zlib')
provides=('libcurl.so')
options=('strip' 'debug')
source=("http://curl.haxx.se/download/$pkgname-$pkgver.tar.gz"{,.asc}
0001-connect-Try-all-addresses-in-first-connection-attemp.patch
curlbuild.h)
prepare() {
cd "$pkgname-$pkgver"
patch -Np1 <"$srcdir"/0001-connect-Try-all-addresses-in-first-connection-attemp.patch
}
build() {
cd "$pkgname-$pkgver"
./configure \
--prefix=/usr \
--mandir=/usr/share/man \
--disable-ldap \
--disable-ldaps \
--enable-ipv6 \
--enable-manual \
--enable-versioned-symbols \
--enable-threaded-resolver \
--without-libidn \
--with-random=/dev/urandom \
--with-ca-bundle=/etc/ssl/certs/ca-certificates.crt
make
}
package() {
cd "$pkgname-$pkgver"
make DESTDIR="$pkgdir" install
local ptrsize=$(cpp <<<'__SIZEOF_POINTER__' | sed '/^#/d')
case $ptrsize in
8) _curlbuild=curlbuild-64.h ;;
4) _curlbuild=curlbuild-32.h ;;
*) error "unknown pointer size for architecture: %s bytes" "$ptrsize"
exit 1
;;
esac
# license
install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
# devel
mv "$pkgdir/usr/include/curl/curlbuild.h" "$pkgdir/usr/include/curl/$_curlbuild"
install -m644 "$srcdir/curlbuild.h" "$pkgdir/usr/include/curl/curlbuild.h"
}
md5sums=('d5b7edccbd1793e3549842e01331da20'
'SKIP'
'ee755b0e886207fc1e8154e426c46ca7'
'751bd433ede935c8fae727377625a8ae')
|
