blob: afa6928c6d2b8d26e47e843a84144c0f25fb518b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
|
# Maintainer: Dave Reisner <dreisner@archlinux.org>
# Contributor: Angel Velasquez <angvp@archlinux.org>
# Contributor: Eric Belanger <eric@archlinux.org>
# Contributor: Lucien Immink <l.immink@student.fnt.hvu.nl>
# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
pkgname=curl
pkgver=7.64.0
pkgrel=9
pkgdesc="An URL retrieval utility and library"
arch=('x86_64')
url="https://curl.haxx.se"
license=('MIT')
depends=('ca-certificates' 'krb5' 'libssh2' 'openssl' 'zlib' 'libpsl' 'libnghttp2'
'libidn2' 'libidn2.so')
provides=('libcurl.so')
source=("https://curl.haxx.se/download/$pkgname-$pkgver.tar.gz"{,.asc}
"0001-connection_check-set-data-to-the-transfer-doing-the-.patch"
"0001-connection_check-restore-original-conn-data-after-th.patch"
"0001-singlesocket-fix-the-sincebefore-placement.patch"
"0001-multi-remove-verbose-Expire-in-messages.patch")
sha512sums=('ea0e68f9cbf2eb4f235d8506962dcc7709f769ef3526c0e4c130fdaf7186a1a13b303c6ce919cb9125bbf7c64ddf4f8efb3d9269b906f856e6d7b3def027fb81'
'SKIP'
'e9fdd70ec6798f48080582e4cb554fc4cd247075c293c66dcf8b27cab151def1c709c306e4dc8a1439b9843f31fe51248b5d6c7f5183e4af65819a084fddcb1f'
'adcbf6309e5d69ede876966790dd504da3097a9e03fedf77d44e10fddcb24a5eaa29b4c9229c813d54bd0c2141211e46b50ca58d89608f7c391434e469316cbd'
'17c8c19e874bfed0736d579300be5a94f87467d1a2c346fe4dca1698fb73c05d02639cf712c95125f32bbd869457d60be4a1ca0f3d5cbc8b091bb35eb2594b15'
'f09b63c36bd958c35bf6e3885efe46fea75fa2780510cac66220bfc1d771de9040560586e0672dac5eb7db7acf67051cf74e56518a8ada6f691c6d8f9dc84fa4')
validpgpkeys=('27EDEAF22F3ABCEB50DB9A125CC908FDB71E12C2') # Daniel Stenberg
prepare() {
cd "$pkgname-$pkgver"
patch -Np1 < ../0001-multi-remove-verbose-Expire-in-messages.patch
# Crash in cargo:
# https://github.com/curl/curl/issues/3541
patch -Np1 < ../0001-connection_check-set-data-to-the-transfer-doing-the-.patch
patch -Np1 < ../0001-connection_check-restore-original-conn-data-after-th.patch
# https://bugs.archlinux.org/task/61688
patch -Np1 < ../0001-singlesocket-fix-the-sincebefore-placement.patch
}
build() {
cd "$pkgname-$pkgver"
./configure \
--prefix=/usr \
--mandir=/usr/share/man \
--disable-ldap \
--disable-ldaps \
--disable-manual \
--enable-ipv6 \
--enable-versioned-symbols \
--enable-threaded-resolver \
--with-gssapi \
--with-libssh2 \
--with-random=/dev/urandom \
--with-ca-bundle=/etc/ssl/certs/ca-certificates.crt
make
}
package() {
cd "$pkgname-$pkgver"
make DESTDIR="$pkgdir" install
make DESTDIR="$pkgdir" install -C scripts
# license
install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 COPYING
}
|
