blob: 32a2d2febc687b86e81a938f7f349b1b60a53de8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
|
# $Id$
# Maintainer: Jan de Groot <jgc@archlinux.org>
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: Tom Gundersen <teg@jklm.no>
# Contributor: Link Dupont <link@subpop.net>
pkgbase=dbus
pkgname=(dbus dbus-docs)
pkgver=1.12.6
pkgrel=1
pkgdesc="Freedesktop.org message bus system"
url="https://wiki.freedesktop.org/www/Software/dbus/"
arch=(x86_64)
license=(GPL custom)
depends=(libsystemd expat)
makedepends=(systemd xmlto docbook-xsl python yelp-tools doxygen git autoconf-archive graphviz)
_commit=a723baa2bc7e91fc9b1926cda1ce53e9301de4d8 # tags/dbus-1.12.6^0
source=("git+https://anongit.freedesktop.org/git/dbus/dbus#commit=$_commit"
'dbus.sysusers')
sha256sums=('SKIP'
'ee7a7a4b2f944cb2e64b9e760efb82589d81872b5b70268356fb73c83c394845')
validpgpkeys=('DA98F25C0871C49A59EAFF2C4DE8FF2A63C7CC90' # Simon McVittie <simon.mcvittie@collabora.co.uk>
'3C8672A0F49637FE064AC30F52A43A1E4B77B059') # Simon McVittie <simon.mcvittie@collabora.co.uk>
pkgver() {
cd $pkgbase
git describe --tags | sed 's/^dbus-//;s/-/+/g'
}
prepare() {
cd $pkgbase
# Reduce docs size
printf '%s\n' >>Doxyfile.in \
HAVE_DOT=yes DOT_IMAGE_FORMAT=svg INTERACTIVE_SVG=yes
NOCONFIGURE=1 ./autogen.sh
}
build() {
cd $pkgbase
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
--libexecdir=/usr/lib/dbus-1.0 --with-dbus-user=dbus \
--with-system-pid-file=/run/dbus/pid \
--with-system-socket=/run/dbus/system_bus_socket \
--with-console-auth-dir=/run/console/ \
--enable-inotify --disable-static \
--disable-verbose-mode --disable-asserts \
--with-systemdsystemunitdir=/usr/lib/systemd/system \
--enable-systemd --enable-user-session
make
}
check() {
cd $pkgbase
make check
}
package_dbus() {
provides=(libdbus)
conflicts=(libdbus)
replaces=(libdbus)
cd $pkgbase
make DESTDIR="$pkgdir" install
rm -r "$pkgdir/var/run"
install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgbase/COPYING"
# We have a pre-assigned uid (81)
install -m644 "$srcdir/dbus.sysusers" "$pkgdir/usr/lib/sysusers.d/dbus.conf"
# Split docs
mv "$pkgdir/usr/share/doc" "$srcdir"
}
package_dbus-docs() {
pkgdesc+=" (documentation)"
depends=(dbus)
install -d "$pkgdir/usr/share/licenses"
ln -s dbus "$pkgdir/usr/share/licenses/dbus-docs"
mv doc "$pkgdir/usr/share"
}
|
