blob: e6a7db4a2c335bba6a31aa21c09864392e405f96 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
|
# $Id: PKGBUILD 141151 2011-10-24 22:00:23Z dan $
# Maintainer: Dan McGee <dan@archlinux.org>
pkgname=git
pkgver=1.7.7.1
pkgrel=2
pkgdesc="the fast distributed version control system"
arch=(i686 x86_64)
url="http://git-scm.com/"
license=('GPL2')
#depends=('curl' 'expat>=2.0' 'perl-error' 'perl>=5.14.0' 'openssl' 'pcre')
depends=('curl' 'expat>=2.0' 'perl-error' 'perl' 'openssl' 'pcre')
makedepends=('python2' )
optdepends=('tk: gitk and git gui'
'perl-libwww: git svn'
'perl-term-readkey: git svn'
'perl-mime-tools: git send-email'
'perl-net-smtp-ssl: git send-email TLS support'
'perl-authen-sasl: git send-email TLS support'
'python2: various helper scripts'
'subversion: git svn'
'cvsps: git cvsimport')
replaces=('git-core')
provides=('git-core')
backup=('etc/conf.d/git-daemon.conf')
#source=("http://kernel.org/pub/software/scm/git/${pkgname}-${pkgver}.tar.bz2"
# "http://kernel.org/pub/software/scm/git/git-manpages-$pkgver.tar.bz2"
source=("http://git-core.googlecode.com/files/git-$pkgver.tar.gz"
"http://git-core.googlecode.com/files/git-manpages-$pkgver.tar.gz"
git-daemon
git-daemon.conf)
changelog=ChangeLog
build() {
export PYTHON_PATH='/usr/bin/python2'
cd "$srcdir/$pkgname-$pkgver"
make prefix=/usr gitexecdir=/usr/lib/git-core \
CFLAGS="$CFLAGS" LDFLAGS="$LDFLAGS" \
USE_LIBPCRE=1 \
NO_CROSS_DIRECTORY_HARDLINKS=1
# cd contrib/emacs
# make prefix=/usr
}
package() {
export PYTHON_PATH='/usr/bin/python2'
cd "$srcdir/$pkgname-$pkgver"
make prefix=/usr gitexecdir=/usr/lib/git-core \
CFLAGS="$CFLAGS" LDFLAGS="$LDFLAGS" \
USE_LIBPCRE=1 \
NO_CROSS_DIRECTORY_HARDLINKS=1 \
INSTALLDIRS=vendor DESTDIR="$pkgdir" install
# bash completion
mkdir -p "$pkgdir"/etc/bash_completion.d/
install -m644 ./contrib/completion/git-completion.bash "$pkgdir"/etc/bash_completion.d/git
# more contrib stuff
cp -a ./contrib $pkgdir/usr/share/git/
# scripts are for python 2.x
sed -i 's|#![ ]*/usr/bin/env python|#!/usr/bin/env python2|' \
$(find "$pkgdir" -name '*.py') \
"$pkgdir"/usr/share/git/{fast-import/git-p4,gitview/gitview}
# emacs interface
# cd contrib/emacs
# make prefix=/usr DESTDIR="$pkgdir" install
# how 'bout some manpages?
for mansect in man1 man5 man7; do
for manpage in "$srcdir"/$mansect/*; do
install -D -m644 $manpage "$pkgdir"/usr/share/man/$mansect/$(basename $manpage)
done
done
# remove perllocal.pod, .packlist, and empty directories.
rm -rf "$pkgdir"/usr/lib/perl5
# git daemon script
install -D -m755 "$srcdir"/git-daemon "$pkgdir"/etc/rc.d/git-daemon
install -D -m644 "$srcdir"/git-daemon.conf "$pkgdir"/etc/conf.d/git-daemon.conf
}
md5sums=('7cfb3e7ea585037272a7ad8e35f4ac0a'
'b6ec6c3a08855b7393284675643be95c'
'8e2648910fd5dd4f1c41d3c7fa9e9156'
'2e42bf97779a1c6411d89043334c9e78')
sha256sums=('6a7909226b2b249c7970b0d36054dbcfe58e6558cc4d671ea1f5ac6a69d8cf4f'
'28904942a0e91d601d731a9fe0bf26c2fe595d8a69a9c2a4da3ec66286c50db5'
'2e0a50bdaf8f387a499895e1c204bff78244eaa72b78187c8a84ef40c0b82598'
'e8bfe29d8393d2b87517c4dd56ea834b213aa00bf3d7fcde4ead3457cadbbc68')
|
