blob: 5b281a242cfa781a2411ff6b2a30154130dcc788 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
|
# $Id: PKGBUILD 90230 2010-09-09 13:16:45Z dan $
# Maintainer: Dan McGee <dan@archlinux.org>
pkgname=git
pkgver=1.7.2.3
pkgrel=2
pkgdesc="the fast distributed version control system"
arch=(i686 x86_64)
url="http://git-scm.com/"
license=('GPL2')
depends=('curl' 'expat>=2.0' 'perl-error' 'perl>=5.10.0')
makedepends=('python2')
optdepends=('tk: gitk and git gui'
'perl-libwww: git svn'
'perl-term-readkey: git svn'
'perl-net-smtp-ssl: git send-email TLS support'
'subversion: git svn'
'cvsps: git cvsimport')
replaces=('git-core')
provides=('git-core')
backup=('etc/conf.d/git-daemon.conf')
source=("http://kernel.org/pub/software/scm/git/${pkgname}-${pkgver}.tar.bz2" \
"http://kernel.org/pub/software/scm/git/git-manpages-${pkgver}.tar.bz2"
git-daemon
git-daemon.conf)
build() {
export PYTHON_PATH='/usr/bin/python2'
cd "$srcdir/$pkgname-$pkgver"
make prefix=/usr gitexecdir=/usr/lib/git-core || return 1
}
package() {
export PYTHON_PATH='/usr/bin/python2'
cd "$srcdir/$pkgname-$pkgver"
make prefix=/usr gitexecdir=/usr/lib/git-core \
NO_CROSS_DIRECTORY_HARDLINKS=1 \
INSTALLDIRS=vendor DESTDIR=${pkgdir} install || return 1
# bash completion
mkdir -p $pkgdir/etc/bash_completion.d/
install -m644 ./contrib/completion/git-completion.bash $pkgdir/etc/bash_completion.d/git || return 1
# more contrib stuff
cp -a ./contrib $pkgdir/usr/share/git/ || return 1
# scripts are for python 2.x
find "$pkgdir" -name '*.py' | xargs sed -i 's|#!/usr/bin/env python|#!/usr/bin/env python2|'
sed -i 's|#!/usr/bin/python|#!/usr/bin/env python2|' "$pkgdir"/usr/lib/git-core/git-remote-testgit
# emacs interface
mkdir -p $pkgdir/usr/share/emacs/site-lisp
mv $pkgdir/usr/share/git/emacs $pkgdir/usr/share/emacs/site-lisp/git
rm $pkgdir/usr/share/emacs/site-lisp/git/.gitignore
# how 'bout some manpages?
for mansect in man1 man5 man7; do
for manpage in $srcdir/$mansect/*; do
install -D -m644 $manpage $pkgdir/usr/share/man/$mansect/$(basename $manpage)
done
done
# remove perllocal.pod, .packlist, and empty directories.
rm -rf $pkgdir/usr/lib/perl5
# git daemon script
install -D -m755 $srcdir/git-daemon $pkgdir/etc/rc.d/git-daemon
install -D -m644 $srcdir/git-daemon.conf $pkgdir/etc/conf.d/git-daemon.conf
}
md5sums=('d88c06f6442156686deb4b4fbab0954c'
'2ef8d3959c832347c29885627ebc0682'
'd777ff1a239b3d810dcf5d89f9d894af'
'9d065134210aa0dd3f2b40d12d915040')
sha256sums=('6139ec31d0a79cae04f469e73cc1f912162bb8f84ef7621ecc8630989fc81ba1'
'87e00245e10472ee5acdd75bb5a6e2e89c12638b498e0df9edca6201439d47d7'
'd2741714a477029ca1ed63f8584040bcba6a53b2332028f9005feef4ae500113'
'6e1475974fae315c55da344c0527923061ad7d9478d39396d147aea497f501b7')
|
