blob: 2316aa65e10e333ae702b99d0038f8c09cb7c14a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Maintainer: Jan de Groot <jgc@archlinux.org>
pkgbase=gobject-introspection
pkgname=(gobject-introspection gobject-introspection-runtime)
pkgver=1.58.3
pkgrel=1
pkgdesc="Introspection system for GObject-based libraries"
url="https://wiki.gnome.org/Projects/GObjectIntrospection"
arch=(x86_64)
license=(LGPL GPL)
depends=(python python-mako)
makedepends=(cairo git gtk-doc python-sphinx meson)
options=(!emptydirs)
_commit=96e0b3f92624937093f0c683db6968bc53c694eb # tags/1.58.3^0
source=("git+https://gitlab.gnome.org/GNOME/gobject-introspection.git#commit=$_commit")
sha512sums=('SKIP')
pkgver() {
cd $pkgbase
git describe --tags | sed 's/-/+/g'
}
prepare() {
cd $pkgbase
}
build() {
arch-meson $pkgbase build -D cairo=true -D gtk-doc=true
ninja -C build
}
check() {
meson test -C build
}
package_gobject-introspection() {
depends+=("gobject-introspection-runtime=$pkgver-$pkgrel")
DESTDIR="$pkgdir" meson install -C build
python -m compileall -d /usr/lib/gobject-introspection "$pkgdir/usr/lib/gobject-introspection"
python -O -m compileall -d /usr/lib/gobject-introspection "$pkgdir/usr/lib/gobject-introspection"
### Split runtime
mkdir -p "$srcdir/runtime/lib"
mv "$pkgdir"/usr/lib/{lib*,girepository-*} "$srcdir/runtime/lib"
}
package_gobject-introspection-runtime() {
pkgdesc+=" (runtime library)"
depends=(glib2)
mv "$srcdir/runtime" "$pkgdir/usr"
}
|
