blob: 81d2f0e9e1105c72efd20a053a4fc20e932cebda (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# $Id$
# Maintainer: Jan de Groot <jgc@archlinux.org>
pkgname=gtk2
pkgver=2.24.29
pkgrel=1
pkgdesc="GObject-based multi-platform GUI toolkit (legacy)"
arch=(i686 x86_64)
url="http://www.gtk.org/"
depends=(atk pango libxcursor libxinerama libxrandr libxi libxcomposite libxdamage
shared-mime-info cairo libcups gtk-update-icon-cache librsvg)
makedepends=(gobject-introspection python2)
optdepends=('gnome-themes-standard: Default widget theme'
'adwaita-icon-theme: Default icon theme')
license=(LGPL)
install=gtk2.install
source=(https://download.gnome.org/sources/gtk+/2.24/gtk+-$pkgver.tar.xz
gtkrc xid-collision-debug.patch)
sha256sums=('0741c59600d3d810a223866453dc2bbb18ce4723828681ba24aa6519c37631b8'
'bc968e3e4f57e818430130338e5f85a5025e21d7e31a3293b8f5a0e58362b805'
'd758bb93e59df15a4ea7732cf984d1c3c19dff67c94b957575efea132b8fe558')
prepare() {
cd gtk+-$pkgver
patch -Np1 -i ../xid-collision-debug.patch
}
build() {
cd gtk+-$pkgver
CXX=/bin/false ./configure --prefix=/usr \
--sysconfdir=/etc \
--localstatedir=/var \
--with-xinput=yes
# https://bugzilla.gnome.org/show_bug.cgi?id=655517
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
package() {
cd gtk+-$pkgver
make DESTDIR="$pkgdir" install
sed -i "s#env python#env python2#" $pkgdir/usr/bin/gtk-builder-convert
install -Dm644 "$srcdir/gtkrc" "$pkgdir/usr/share/gtk-2.0/gtkrc"
rm "$pkgdir/usr/bin/gtk-update-icon-cache"
}
# vim:set noet sw=4:
|
