blob: 4a6bcc071a6afd196893fa6dc64c27622f7d8903 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# $Id$
# Maintainer: Ronald van Haren <ronald.archlinux.org>
# Contributor: Judd Vinet <jvinet@zeroflux.org>
pkgname=iproute2
pkgver=4.1.1
pkgrel=1
pkgdesc="IP Routing Utilities"
arch=('i686' 'x86_64')
license=('GPL2')
url="http://www.linuxfoundation.org/collaborate/workgroups/networking/iproute2"
depends=('glibc' 'iptables')
makedepends=('linux-atm')
optdepends=('linux-atm: ATM support')
groups=('base')
provides=('iproute')
conflicts=('iproute')
replaces=('iproute')
options=('staticlibs' '!makeflags')
backup=('etc/iproute2/ematch_map' 'etc/iproute2/rt_dsfield' 'etc/iproute2/rt_protos' \
'etc/iproute2/rt_realms' 'etc/iproute2/rt_scopes' 'etc/iproute2/rt_tables')
validpgpkeys=('9F6FC345B05BE7E766B83C8F80A77F6095CDE47E') # Stephen Hemminger
source=("http://www.kernel.org/pub/linux/utils/net/${pkgname}/${pkgname}-${pkgver}.tar."{xz,sign}
iproute2-fhs.patch
unwanted-link-help.patch)
sha1sums=('750c17e720b43041c23fed7b8cf0118c0e841036'
'SKIP'
'2dc6d8f1a2495a0d51eaa303dcc78ecc0c477935'
'3b1335f4025f657f388fbf4e5a740871e3129c2a')
prepare() {
cd "${srcdir}/${pkgname}-${pkgver}"
# set correct fhs structure
patch -Np1 -i "${srcdir}/iproute2-fhs.patch"
# allow operations on links called "h", "he", "hel", "help"
patch -Np1 -i "${srcdir}/unwanted-link-help.patch"
# do not treat warnings as errors
sed -i 's/-Werror//' Makefile
}
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
./configure
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
# libnetlink isn't installed, install it FS#19385
install -Dm644 include/libnetlink.h "${pkgdir}/usr/include/libnetlink.h"
install -Dm644 lib/libnetlink.a "${pkgdir}/usr/lib/libnetlink.a"
# move binaries
cd "${pkgdir}"
mv sbin usr/bin
}
|
