blob: 566c75b41c7c1b090ed386c28c640149891d8597 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
|
# $Id$
# Maintainer: Christian Hesse <mail@eworm.de>
# Maintainer: Ronald van Haren <ronald.archlinux.org>
# Contributor: Judd Vinet <jvinet@zeroflux.org>
pkgbase=iproute2
#pkgname=(iproute2 iproute2-doc)
pkgname=(iproute2)
pkgver=4.9.0
pkgrel=1
pkgdesc='IP Routing Utilities'
arch=('i686' 'x86_64')
license=('GPL2')
url='http://www.linuxfoundation.org/collaborate/workgroups/networking/iproute2'
#makedepends=('iptables' 'linux-atm' 'linuxdoc-tools' 'texlive-bin' 'texlive-core' 'texlive-latexextra')
makedepends=('iptables' 'linux-atm')
options=('staticlibs' '!makeflags')
validpgpkeys=('9F6FC345B05BE7E766B83C8F80A77F6095CDE47E') # Stephen Hemminger
source=("https://www.kernel.org/pub/linux/utils/net/${pkgbase}/${pkgbase}-${pkgver}.tar."{xz,sign}
'0001-make-iproute2-fhs-compliant.patch')
sha256sums=('c0f30f043f7767cc1b2cd2197b08d4e9b2392c95823fabe30bbce308c30116c4'
'SKIP'
'f60fefe4c17d3b768824bb50ae6416292bcebba06d73452e23f4147b46b827d3')
prepare() {
cd "${srcdir}/${pkgbase}-${pkgver}"
# set correct fhs structure
patch -Np1 -i "${srcdir}/0001-make-iproute2-fhs-compliant.patch"
# do not treat warnings as errors
sed -i 's/-Werror//' Makefile
}
build() {
cd "${srcdir}/${pkgbase}-${pkgver}"
./configure
make
# cd "${srcdir}/${pkgbase}-${pkgver}/doc/"
# make html pdf
}
package_iproute2() {
depends=('glibc' 'iptables')
optdepends=('linux-atm: ATM support')
groups=('base')
provides=('iproute')
conflicts=('iproute')
replaces=('iproute')
backup=('etc/iproute2/ematch_map' 'etc/iproute2/rt_dsfield' 'etc/iproute2/rt_protos' \
'etc/iproute2/rt_realms' 'etc/iproute2/rt_scopes' 'etc/iproute2/rt_tables')
cd "${srcdir}/${pkgbase}-${pkgver}"
make DESTDIR="${pkgdir}" SBINDIR="/usr/bin" install
# remove documentation
rm -rf "${pkgdir}/usr/share/doc/"
# libnetlink isn't installed, install it FS#19385
install -Dm0644 include/libnetlink.h "${pkgdir}/usr/include/libnetlink.h"
install -Dm0644 lib/libnetlink.a "${pkgdir}/usr/lib/libnetlink.a"
}
package_iproute2-doc() {
pkgdesc='IP Routing Utilities documentation'
cd "${srcdir}/${pkgbase}-${pkgver}"
make DESTDIR="${pkgdir}" install
# documentation is included in default install target... So clean up here.
find "${pkgdir}/" ! -type d ! -regex '.*examples.*' -delete
find "${pkgdir}/" -empty -delete
find "${pkgdir}/" -name '*.sgml' -delete
find "${pkgdir}/" -name '*.tex' -delete
install -m0644 doc/*.html doc/*.pdf "${pkgdir}/usr/share/doc/iproute2/"
}
|
