summaryrefslogtreecommitdiffstats
path: root/abs/core/libdvdnav/PKGBUILD
blob: 4bd01d5f68944010120035cfc6ab5ad2cca99296 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
# $Id$
# Maintainer: Jan de Groot <jgc@archlinux.org>
# Contributor: Arjan <arjan@archlinux.org>
# contributor Sarah Hay <sarahhay@mb.sympatico.ca>

pkgname=libdvdnav
pkgver=5.0.3
pkgrel=1
pkgdesc="The library for xine-dvdnav plugin."
arch=('i686' 'x86_64')
license=('GPL')
url="http://dvdnav.mplayerhq.hu/"
depends=('libdvdread')
makedepends=('git')
source=(git+https://code.videolan.org/videolan/libdvdnav.git#tag=$pkgver
        fix-crash-describe_title.patch)
sha256sums=('SKIP'
            '6a8e9c777dd9dbfa8a7f981796bd7a60412e3a5c7a8400253c567d956412c64b')

prepare() {
  cd $pkgname
  patch -Np1 -i ../fix-crash-describe_title.patch
  autoreconf -fi
}

build() {
  cd $pkgname
  ./configure --prefix=/usr
  make
}

package() {
  cd $pkgname
  make DESTDIR="${pkgdir}" install
}