abs/core/libogg/PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38

# $Id: PKGBUILD 134991 2011-08-09 20:12:08Z eric $
# Maintainer: 
# Contributor: John Proctor <jproctor@prium.net>

pkgname=libogg
pkgver=1.3.0
pkgrel=1
pkgdesc="Ogg bitstream and framing library"
arch=('i686' 'x86_64')
url="http://www.xiph.org/ogg/"
license=('BSD')
depends=('glibc')
options=('!libtool')
source=(http://downloads.xiph.org/releases/ogg/$pkgname-$pkgver.tar.xz
        config_types.h)
md5sums=('84a35715170f2cd4c77a4448772b95d5'
         'a4d786b1b1955cb85b64fd16cbbee3f9')

build() {
  cd "$srcdir/${pkgname}-${pkgver}"
  ./configure --prefix=/usr 
  make
}

package() {
  cd "$srcdir/${pkgname}-${pkgver}"
  make DESTDIR="$pkgdir" install

# install BSD license
  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"

# Resolve multilib conflict
  if [[ $CARCH == "x86_64" ]]; then
    mv "$pkgdir"/usr/include/ogg/config_types{,-64}.h
    install -m 644 "$srcdir/config_types.h" \
      "${pkgdir}/usr/include/ogg/config_types.h"
  fi
}