blob: 594b4ef17d24bfa4b30ee57c8e97b08c6ed70870 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Maintainer: Jan de Groot <jgc@archlinux.org>
# Contributor: Tom Gundersen <teg@jklm.no>
# Contributor: John Proctor <jproctor@prium.net>
pkgname=libxml2
pkgver=2.9.9
pkgrel=1
pkgdesc='XML parsing library, version 2'
url='http://www.xmlsoft.org/'
arch=(x86_64)
license=(MIT)
depends=(zlib readline ncurses xz icu)
makedepends=(python2 python git)
_commit=f8a8c1f59db355b46962577e7b74f1a1e8149dc6 # tags/v2.9.9^0
source=("git+https://git.gnome.org/browse/libxml2#commit=$_commit"
https://www.w3.org/XML/Test/xmlts20130923.tar.gz)
sha256sums=('SKIP'
'9b61db9f5dbffa545f4b8d78422167083a8568c59bd1129f94138f936cf6fc1f')
pkgver() {
cd $pkgname
git describe --always --tags | sed 's/-rc/rc/;s/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
mkdir build-py{2,3}
cd $pkgname
NOCONFIGURE=1 ./autogen.sh
}
_build() (
cd build-py$1
../$pkgname/configure \
--prefix=/usr \
--with-threads \
--with-history \
--with-python=/usr/bin/python$1 \
--with-icu
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0 /g' libtool
PYTHONHASHSEED=0 make
find doc -type f -exec chmod 0644 {} +
)
build() {
_build 2
_build 3
}
check() {
cd build-py2
ln -s ../xmlconf
make check
}
package() {
make -C build-py2 DESTDIR="$pkgdir" install
make -C build-py3/python DESTDIR="$pkgdir" install
install -Dm 644 build-py2/COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
}
# vim: ts=2 sw=2 et:
|
