abs/core/m4/PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37

# $Id: PKGBUILD 142068 2011-11-04 23:36:00Z allan $
# Maintainer: Allan McRae <allan@archlinux.org>
# Contributor: Andreas Radke <andyrtr@archlinux.org>

pkgname=m4
pkgver=1.4.16
pkgrel=2
pkgdesc="The GNU macro processor"
arch=('i686' 'x86_64')
url="http://www.gnu.org/software/m4"
license=('GPL3')
groups=('base-devel')
depends=('glibc' 'bash')
install=m4.install
source=(ftp://ftp.gnu.org/gnu/m4/$pkgname-$pkgver.tar.xz{,.sig}
        m4-1.4.16-readlink-einval.patch)
md5sums=('7548ec061a1ba993790159764f522d0e'
         'eebe5c94e74e7551e2e30c5844f1b653'
         'cea138fa9b568d06e46269611cec8dd0')

build() {
  cd ${srcdir}/$pkgname-$pkgver
  patch -Np1 -i $srcdir/m4-1.4.16-readlink-einval.patch
  sed -i '/gets is a security hole/d' lib/stdio.in.h
  ./configure --prefix=/usr
  make
}

check() {
  cd ${srcdir}/$pkgname-$pkgver
  make check
}

package() {
  cd ${srcdir}/$pkgname-$pkgver
  make prefix=${pkgdir}/usr install
}