blob: 7dbdf3fc207b6f8d49101b5f864ec082cb0508e5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
|
# $Id$
# Maintainer: Ionut Biru <ibiru@archlinux.org>
# Maintainer: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: Hugo Doria <hugo@archlinux.org>
pkgbase=mplayer
pkgname=('mplayer' 'mencoder')
pkgver=37224
pkgrel=3
arch=('i686' 'x86_64')
makedepends=(
'libxxf86dga' 'libxxf86vm' 'libmad' 'libxinerama' 'sdl' 'lame' 'libtheora'
'xvidcore' 'libmng' 'libxss' 'libgl' 'smbclient' 'aalib' 'libcaca'
'faac' 'faad2' 'lirc-utils' 'libxvmc' 'enca' 'libvdpau' 'opencore-amr'
'libdca' 'a52dec' 'schroedinger' 'libvpx' 'fribidi' 'unzip' 'mesa'
'live-media' 'yasm' 'git' 'fontconfig' 'mpg123' 'ladspa' 'libass' 'libbluray'
'libcdio-paranoia' 'opus' 'subversion' 'x264' 'libx264' 'rtmpdump' 'gsm'
)
license=('GPL')
url='http://www.mplayerhq.hu/'
options=('!buildflags' '!emptydirs')
source=($pkgbase-$pkgver::svn://svn.mplayerhq.hu/mplayer/trunk#revision=$pkgver
http://ffmpeg.org/releases/ffmpeg-2.2.10.tar.bz2
mplayer.desktop
cdio-includes.patch
include-samba-4.0.patch
giflib51.patch
revert-icl-fixes.patch)
md5sums=('SKIP'
'f40a829f5075c8ee901e5dbc6d40c209'
'62f44a58f072b2b1a3c3d3e4976d64b3'
'7b5be7191aafbea64218dc4916343bbc'
'868a92bdef148df7f38bfa992b26ce9d'
'14461fb94b7aa5dda091ba4f737df2d9'
'3579402002b7302fdf2d146639333efd')
pkgver() {
cd $pkgbase-$pkgver
svnversion
}
prepare() {
cd $pkgbase-$pkgver
mv ../ffmpeg-2.2.10 ./ffmpeg
patch -p0 -i ../cdio-includes.patch
patch -p1 -i ../include-samba-4.0.patch
patch -Np0 -i ../giflib51.patch
patch -Np0 -i ../revert-icl-fixes.patch
./version.sh
}
build() {
cd $pkgbase-$pkgver
./configure --prefix=/usr \
--enable-runtime-cpudetection \
--disable-gui \
--disable-arts \
--disable-liblzo \
--disable-speex \
--disable-openal \
--disable-libdv \
--disable-musepack \
--disable-esd \
--disable-mga \
--disable-ass-internal \
--disable-cdparanoia \
--enable-xvmc \
--enable-radio \
--enable-radio-capture \
--enable-smb \
--language=all \
--confdir=/etc/mplayer
[[ "$CARCH" = "i686" ]] && sed 's|-march=i486|-march=i686|g' -i config.mak
make
}
package_mplayer() {
pkgdesc='Media player for Linux'
install=mplayer.install
backup=('etc/mplayer/codecs.conf' 'etc/mplayer/input.conf')
depends=(
'desktop-file-utils' 'ttf-font' 'enca' 'libxss' 'a52dec' 'libvpx'
'lirc-utils' 'libx264' 'libmng' 'libdca' 'aalib' 'lame' 'fontconfig'
'libgl' 'libxinerama' 'libvdpau' 'smbclient' 'xvidcore'
'opencore-amr' 'libmad' 'sdl' 'libtheora' 'libcaca' 'libxxf86dga'
'fribidi' 'libjpeg' 'faac' 'faad2' 'libxvmc' 'schroedinger' 'mpg123'
'libass' 'libxxf86vm' 'libbluray' 'libcdio-paranoia' 'opus' 'rtmpdump'
'gsm'
)
cd $pkgbase-$pkgver
make DESTDIR="$pkgdir" install-mplayer install-mplayer-man
install -Dm644 etc/{codecs.conf,input.conf,example.conf} \
"$pkgdir/etc/mplayer/"
# desktop file (FS#14770)
install -Dm644 ../mplayer.desktop \
"$pkgdir"/usr/share/applications/mplayer.desktop
install -Dm644 etc/mplayer256x256.png \
"$pkgdir"/usr/share/pixmaps/mplayer.png
}
package_mencoder() {
pkgdesc='Free command line video decoding, encoding and filtering tool'
depends=(
'enca' 'a52dec' 'libvpx' 'libx264' 'libmng' 'libdca' 'bzip2' 'lame'
'alsa-lib' 'fontconfig' 'giflib' 'libpng' 'smbclient' 'xvidcore'
'opencore-amr' 'libmad' 'libtheora' 'fribidi' 'libjpeg' 'faac' 'faad2'
'schroedinger' 'mpg123' 'libass' 'libbluray' 'libcdio-paranoia'
'libvorbis' 'opus' 'rtmpdump' 'gsm'
)
make -C $pkgbase-$pkgver DESTDIR="$pkgdir" install-mencoder install-mencoder-man
find "$pkgdir"/usr/share/man -name mplayer.1 -exec rename mplayer.1 mencoder.1 {} +
}
|
