blob: 54c17ed21d22b0954e6a6a62f59e75e00481962b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# $Id$
# Maintainer: Ionut Biru <ibiru@archlinux.org>
pkgname=p11-kit
pkgver=0.23.2
pkgrel=1
pkgdesc="Library to work with PKCS#11 modules"
arch=(i686 x86_64)
url="http://p11-glue.freedesktop.org"
license=('BSD')
depends=('glibc' 'libtasn1' 'libffi')
makedepends=('gtk-doc')
source=($url/releases/$pkgname-$pkgver.tar.gz{,.sig}
libnssckbi-compat.patch)
sha256sums=('ba726ea8303c97467a33fca50ee79b7b35212964be808ecf9b145e9042fdfaf0'
'SKIP'
'8f763cdbc6c0ca6c5a7898f9fd6f3018b7ac5b1aca36f67c6c813343c2962962')
validpgpkeys=('C0F67099B808FB063E2C81117BFB1108D92765AF')
prepare() {
cd $pkgname-$pkgver
# Build and install an additional library (libnssckbi-p11-kit.so) which
# is a copy of p11-kit-trust.so but uses the same label for root certs as
# libnssckbi.so ("Builtin Object Token" instead of "Default Trust")
# https://bugs.freedesktop.org/show_bug.cgi?id=66161
patch -Np1 -i ../libnssckbi-compat.patch
autoreconf -vi
}
build() {
cd $pkgname-$pkgver
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--enable-doc \
--with-module-path=/usr/lib/pkcs11 \
--with-trust-paths=/etc/ca-certificates/trust-source:/usr/share/ca-certificates/trust-source
make
}
check() {
cd $pkgname-$pkgver
make check
}
package() {
cd $pkgname-$pkgver
make DESTDIR="$pkgdir" install
install -Dm644 COPYING $pkgdir/usr/share/licenses/$pkgname/COPYING
ln -srf "$pkgdir/usr/bin/update-ca-trust" "$pkgdir/usr/lib/p11-kit/trust-extract-compat"
}
# vim:set ts=2 sw=2 et:
|
