blob: 1bcd44efd66a22978153a7aa2bd2f330b0fba2be (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# $Id$
# Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
# Contributor: Peter Baldwin <bald_pete@hotmail.com>
pkgname=('python-jinja' 'python2-jinja')
pkgver=2.10
pkgrel=1
pkgdesc="A simple pythonic template language written in Python"
arch=('any')
url="http://jinja.pocoo.org/"
license=('BSD')
makedepends=('python-setuptools' 'python2-setuptools' 'python-markupsafe'
'python2-markupsafe')
source=(https://pypi.org/packages/source/J/Jinja2/Jinja2-$pkgver.tar.gz)
sha256sums=('f84be1bb0040caca4cea721fcbbbbd61f9be9464ca236387158b0feea01914a4')
build() {
cd "$srcdir"
rm -rf python{2,3}-build
for builddir in python{2,3}-build; do
cp -r Jinja2-$pkgver $builddir
pushd $builddir
${builddir%-build} setup.py build
popd
done
}
package_python-jinja() {
depends=('python-setuptools' 'python-markupsafe')
cd "$srcdir/python3-build"
python3 setup.py install --root="$pkgdir" -O1
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
package_python2-jinja() {
depends=('python2-setuptools' 'python2-markupsafe')
cd "$srcdir/python2-build"
python2 setup.py install --root="$pkgdir" -O1
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
# vim:set ts=2 sw=2 et:
|
