blob: eee0bf051bc5e0afc89a5142b0960111667a9292 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
|
# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Massimiliano Torromeo <massimiliano.torromeo@gmail.com>
pkgbase=python-requests
pkgname=('python-requests' 'python2-requests')
pkgver=2.25.0
pkgrel=1
pkgdesc="Python HTTP for Humans"
arch=('any')
url="http://python-requests.org"
license=('Apache')
makedepends=('python-setuptools' 'python2-setuptools' 'python-chardet' 'python2-chardet'
'python-urllib3' 'python2-urllib3' 'python-idna' 'python2-idna')
checkdepends=('python-pytest-httpbin' 'python-pytest-mock' 'python-pysocks' 'python-pyopenssl')
source=("$pkgbase-$pkgver.tar.gz::https://github.com/psf/requests/archive/v$pkgver.tar.gz"
certs.patch)
sha512sums=('f60d8dbbc7aaebaedc7647ab2cec1fffd01547ea3340b91d9c7fea51fde4cb932aaf81e3b8aac9f4be11243e4fc44c8266a69db5f52c4eb2afb1b7714c150b95'
'424a3bb01b23409284f6c9cd2bc22d92df31b85cfd96e1d1b16b5d68adeca670dfed4fff7977d8b10980102b0f780eacc465431021fcd661f3a17168a02a39a3')
prepare() {
cd "$srcdir"/requests-$pkgver
sed -e '/certifi/d' \
-e "s/,<.*'/'/" \
-i setup.py
patch -p1 -i "$srcdir"/certs.patch
cd "$srcdir"
cp -a requests-$pkgver{,-py2}
find requests-$pkgver-py2 -name \*.py -exec sed -r 's|^#!(.*)python$|#!\1python2|' -i {} +
}
build() {
cd "$srcdir"/requests-$pkgver
python setup.py build
cd "$srcdir"/requests-$pkgver-py2
python2 setup.py build
}
check() {
# Seems to be a problem about pytest-httpbin
cd requests-$pkgver
pytest tests --deselect tests/test_requests.py::TestRequests::test_https_warnings
}
package_python-requests() {
depends=('python-urllib3' 'python-chardet' 'python-idna')
optdepends=('python-pysocks: SOCKS proxy support')
cd "$srcdir"/requests-$pkgver
python setup.py install --skip-build -O1 --root="$pkgdir"
}
package_python2-requests() {
depends=('python2-urllib3' 'python2-chardet' 'python2-idna')
optdepends=('python2-ndg-httpsclient: HTTPS requests with SNI support'
'python2-grequests: asynchronous requests with gevent'
'python2-pysocks: SOCKS proxy support')
cd "$srcdir"/requests-$pkgver-py2
python2 setup.py install --skip-build -O1 --root="$pkgdir"
}
|
