blob: 072d35fca8d8a992827c6ca1beb636c29f99487a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: Felix Yan <felixonmars@archlinux.org>
pkgbase=python-zope-deferredimport
pkgname=('python-zope-deferredimport' 'python2-zope-deferredimport')
pkgver=4.3
pkgrel=2
pkgdesc="Allows you to perform imports names that will only be resolved when used in the code"
arch=('any')
url="https://github.com/zopefoundation/zope.deferredimport"
license=('ZPL')
makedepends=('python-setuptools' 'python2-setuptools' 'python-zope-proxy' 'python2-zope-proxy')
checkdepends=('python-zope-testrunner' 'python2-zope-testrunner')
source=("$pkgbase-$pkgver.tar.gz::https://github.com/zopefoundation/zope.deferredimport/archive/$pkgver.tar.gz")
sha512sums=('0b62cf6caa7709dbb6b0ae85bf9c5e24909c79af57da8e3d081e69ff9f73fc60fbe5a83cdfe795551eeee3c045d3783a09cb3e6eb3964a44e6fbbea149ca3f8a')
prepare() {
# Build in separated dir to avoid polluting .pyc files
cp -a zope.deferredimport-$pkgver{,-py2}
}
build() {
cd "$srcdir"/zope.deferredimport-$pkgver
python setup.py build
cd "$srcdir"/zope.deferredimport-$pkgver-py2
python2 setup.py build
}
check() {
cd "$srcdir"/zope.deferredimport-$pkgver
PYTHONPATH="$PWD/build/lib:$PYTHONPATH" python -m zope.testrunner --test-path=src
cd "$srcdir"/zope.deferredimport-$pkgver-py2
PYTHONPATH="$PWD/build/lib:$PYTHONPATH" python2 -m zope.testrunner --test-path=src
}
package_python-zope-deferredimport() {
depends=('python-setuptools' 'python-zope-proxy')
cd zope.deferredimport-$pkgver
python setup.py install --root="$pkgdir" --optimize=1
}
package_python2-zope-deferredimport() {
depends=('python2-setuptools' 'python2-zope-proxy')
cd zope.deferredimport-$pkgver-py2
python2 setup.py install --root="$pkgdir" --optimize=1
}
# vim:set ts=2 sw=2 et:
|
