blob: fa77dacddae4f3a5a8f43fcb28d018862b479fb1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
|
# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: kfgz <kfgz@interia.pl>
pkgname=x265
pkgver=3.0
pkgrel=1
pkgdesc='Open Source H265/HEVC video encoder'
arch=('x86_64')
url='https://bitbucket.org/multicoreware/x265'
license=('GPL')
depends=()
makedepends=('cmake' 'mercurial' 'nasm')
provides=('libx265.so')
source=("hg+https://bitbucket.org/multicoreware/x265#tag=${pkgver}")
sha256sums=('SKIP')
prepare() {
cd x265
for d in 8 10 12; do
if [[ -d build-$d ]]; then
rm -rf build-$d
fi
mkdir build-$d
done
}
build() {
cd x265/build-12
cmake ../source \
-DCMAKE_INSTALL_PREFIX='/usr' \
-DHIGH_BIT_DEPTH='TRUE' \
-DMAIN12='TRUE' \
-DEXPORT_C_API='FALSE' \
-DENABLE_CLI='FALSE' \
-DENABLE_SHARED='FALSE'
make
cd ../build-10
cmake ../source \
-DCMAKE_INSTALL_PREFIX='/usr' \
-DHIGH_BIT_DEPTH='TRUE' \
-DEXPORT_C_API='FALSE' \
-DENABLE_CLI='FALSE' \
-DENABLE_SHARED='FALSE'
make
cd ../build-8
ln -s ../build-10/libx265.a libx265_main10.a
ln -s ../build-12/libx265.a libx265_main12.a
cmake ../source \
-DCMAKE_INSTALL_PREFIX='/usr' \
-DENABLE_SHARED='TRUE' \
-DENABLE_HDR10_PLUS='TRUE' \
-DEXTRA_LIB='x265_main10.a;x265_main12.a' \
-DEXTRA_LINK_FLAGS='-L .' \
-DLINKED_10BIT='TRUE' \
-DLINKED_12BIT='TRUE'
make
}
package() {
cd x265/build-8
make DESTDIR="${pkgdir}" install
}
# vim: ts=2 sw=2 et:
|
