blob: 042fed4c18fe20d70cd387cd900cfe392e9adf12 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
|
# Maintainer: AndyRTR <andyrtr@archlinux.org>
# Maintainer: Jan de Groot <jgc@archlinux.org>
pkgname=xf86-video-intel
_commit=3a2dec17459dea56331430c8481646d538278518 # master
pkgver=2.99.917+860+g3a2dec17
pkgrel=1
epoch=1
arch=(x86_64)
url="https://01.org/linuxgraphics"
license=('custom')
install=$pkgname.install
pkgdesc="X.org Intel i810/i830/i915/945G/G965+ video drivers"
depends=('mesa' 'libxvmc' 'pixman' 'xcb-util>=0.3.9' 'libsystemd')
makedepends=('xorg-server-devel' 'X-ABI-VIDEODRV_VERSION=23' 'libx11' 'libxrender'
# additional deps for intel-virtual-output
'libxrandr' 'libxinerama' 'libxcursor' 'libxtst' 'libxss'
# additional for git snapshot
'git') # 'meson' 'valgrind')
optdepends=('libxrandr: for intel-virtual-output'
'libxinerama: for intel-virtual-output'
'libxcursor: for intel-virtual-output'
'libxtst: for intel-virtual-output'
'libxss: for intel-virtual-output')
replaces=('xf86-video-intel-uxa' 'xf86-video-intel-sna')
provides=('xf86-video-intel-uxa' 'xf86-video-intel-sna')
conflicts=('xorg-server<1.19' 'X-ABI-VIDEODRV_VERSION<23' 'X-ABI-VIDEODRV_VERSION>=24'
'xf86-video-intel-sna' 'xf86-video-intel-uxa' 'xf86-video-i810' 'xf86-video-intel-legacy')
groups=('xorg-drivers')
source=("git+https://anongit.freedesktop.org/git/xorg/driver/xf86-video-intel#commit=$_commit"
0001-SNA-fix-PRIME-output-support-since-xserver-1.20.patch)
sha256sums=('SKIP'
'7cdc310953379ede9693a387ecac6c803cc4c4461df5ad9ab875b35e90a552f5')
#options=('!makeflags')
pkgver() {
cd $pkgname
git describe --tags | sed 's/-/+/g'
}
prepare() {
cd $pkgname
# fix external monitor - FS#58895
# https://bugs.freedesktop.org/show_bug.cgi?id=100086
patch -Np1 -i ../0001-SNA-fix-PRIME-output-support-since-xserver-1.20.patch
NOCONFIGURE=1 ./autogen.sh
# mkdir build
}
build() {
cd $pkgname
# Since pacman 5.0.2-2, hardened flags are now enabled in makepkg.conf
# With them, module fail to load with undefined symbol.
# See https://bugs.archlinux.org/task/55102 / https://bugs.archlinux.org/task/54845
export CFLAGS=${CFLAGS/-fno-plt}
export CXXFLAGS=${CXXFLAGS/-fno-plt}
export LDFLAGS=${LDFLAGS/,-z,now}
./configure --prefix=/usr \
--libexecdir=/usr/lib \
--with-default-dri=3
make
# cd build
# arch-meson $pkgname build \
# -Dwith-default-dri=3
# ninja -C build
}
check() {
cd $pkgname
make check
# meson test -C build
}
package() {
cd $pkgname
make DESTDIR="${pkgdir}" install
# DESTDIR="$pkgdir" ninja -C build install
install -m755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
install -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/"
}
|
