blob: acdf9706bee5f76ddfe6a13e529e4271a9ef2b47 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
|
# Maintainer : Tobias Powalowski <tpowa@archlinux.org>
pkgname=xfsprogs
pkgver=5.8.0
pkgrel=1
pkgdesc="XFS filesystem utilities"
arch=('x86_64')
license=('LGPL')
url="https://xfs.org"
depends=('sh' 'util-linux-libs' 'icu' 'device-mapper')
optdepends=('python: for xfs_scrub_all script'
'smtp-forwarder: for xfs_scrub_fail script')
makedepends=('git')
options=('!makeflags')
source=("git+https://git.kernel.org/pub/scm/fs/xfs/xfsprogs-dev.git#tag=v${pkgver}")
md5sums=('SKIP')
build() {
cd ${pkgname}-dev
make configure
export OPTIMIZER="-march=${CARCH/_/-} -O1"
export DEBUG=-DNDEBUG
./configure --prefix=/usr --sbindir=/usr/bin --with-systemd-unit-dir=/usr/lib/systemd/system
make
}
package() {
cd ${pkgname}-dev
make DIST_ROOT="${pkgdir}" PKG_ROOT_SBIN_DIR="/usr/bin" install install-dev
chown -R root "$pkgdir"
chgrp -R root "$pkgdir"
# add hack as we cannot set rootlibdir
mv "${pkgdir}"/lib/libhandle.so* "${pkgdir}/usr/lib/"
rm -rf "${pkgdir}/lib"
}
|
