blob: 391b14ed1c20d3dd44e8cf7aee23395eb7f3d283 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
# Maintainer: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: Andrzej Giniewicz <gginiu@gmail.com>
# Contributor: Johan Förberg <johan@forberg.se>
pkgname=zstd
pkgver=1.4.5
pkgrel=1
pkgdesc='Zstandard - Fast real-time compression algorithm'
arch=(x86_64)
url='https://www.zstd.net/'
license=(BSD GPL2)
depends=(zlib xz lz4)
makedepends=(gtest)
source=($pkgname-$pkgver.tar.gz::https://github.com/facebook/zstd/archive/v${pkgver}.tar.gz)
sha256sums=('734d1f565c42f691f8420c8d06783ad818060fc390dee43ae0a89f86d0a4f8c2')
build() {
cd $pkgname-$pkgver
make
make zstdmt
make -C contrib/pzstd
}
check() {
cd $pkgname-$pkgver
make check
make -C contrib/pzstd test
}
package() {
cd $pkgname-$pkgver
make PREFIX=/usr DESTDIR="$pkgdir/" install
install -Dm755 zstdmt "$pkgdir/usr/bin/zstdmt"
install -Dm755 contrib/pzstd/pzstd "$pkgdir/usr/bin/pzstd"
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|
