blob: a1cde1dd3aaaff69594355955a5357d62977a5cb (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: Felix Yan <felixonmars@archlinux.org>
# Contributor: Gordian Edenhofer <gordian.edenhofer[at]yahoo[dot]de>
pkgname=certbot
pkgver=0.35.0
pkgrel=1
pkgdesc="A tool to automatically receive and install X.509 certificates to enable TLS on servers. The client will interoperate with the Let’s Encrypt CA which will be issuing browser-trusted certificates for free."
arch=('any')
license=('Apache')
url="https://certbot.eff.org"
depends=('ca-certificates' 'python-acme' 'python-configargparse' 'python-configobj'
'python-cryptography' 'python-mock' 'python-parsedatetime' 'python-pyrfc3339'
'python-pytz' 'python-setuptools' 'python-zope-component' 'python-zope-interface')
checkdepends=('python-pytest-runner')
optdepends=('certbot-apache: Apache plugin for Let’s Encrypt client'
'certbot-nginx: Nginx plugin for Let’s Encrypt client')
replaces=("letsencrypt")
source=("https://pypi.io/packages/source/c/$pkgname/$pkgname-$pkgver.tar.gz"{,.asc})
validpgpkeys=('148C30F6F7E429337A72D992B00B9CC82D7ADF2C'
'1B41B758F9A78C7F444C20FA3E5B4152E3ADB1FD'
'A2CFB51FA275A7286234E7B24D17C995CD9775F2')
sha512sums=('1f135df0b5d43a021b10d0c2e78aea2ed21ad07ee59bb7ed7c3c4e9efcd6288801f86b03f2bc8e18b1367e27f2c9ba53f3de8cdf0128ef93c243c79002c99839'
'SKIP')
build() {
cd "$srcdir"/$pkgname-$pkgver
python setup.py build
}
check() {
cd "$srcdir"/$pkgname-$pkgver
python setup.py pytest
}
package() {
cd "$srcdir"/$pkgname-$pkgver
python setup.py install --root="$pkgdir"
mkdir -p "$pkgdir"/{etc,var/lib,var/log}/letsencrypt
chmod 700 "$pkgdir"/var/log/letsencrypt
}
|
