blob: 0a52614522cf0192ce42cb6c7185cd625ced68bf (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
|
# $Id: PKGBUILD 87764 2010-08-18 09:05:27Z jgc $
# Maintainer: Jan de Groot <jgc@archlinux.org>
pkgname=gstreamer0.10
pkgver=0.10.30
pkgrel=1
pkgdesc="GStreamer Multimedia Framework"
arch=('i686' 'x86_64')
license=('LGPL')
url="http://gstreamer.freedesktop.org/"
depends=('libxml2>=2.7.7' 'glib2>=2.24.1')
makedepends=('intltool' 'pkgconfig' 'gtk-doc' 'gobject-introspection')
options=('!libtool')
source=(${url}/src/gstreamer/gstreamer-${pkgver}.tar.bz2)
sha256sums=('e8ef301be423797ff36a0bb3615930b112b4175634051d19fd655e0ed974532a')
build() {
cd "${srcdir}/gstreamer-${pkgver}"
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --libexecdir=/usr/lib \
--with-package-name="GStreamer (Archlinux)" \
--with-package-origin="http://www.archlinux.org/"
make
}
package() {
cd "${srcdir}/gstreamer-${pkgver}"
make DESTDIR="${pkgdir}" install
cd "${pkgdir}/usr/bin"
#Remove unversioned gst-* binaries to get rid of conflicts
for bins in `ls *-0.10`; do
rm -f ${bins/-0.10/}
done
}
|
