blob: d85633511787a4851ae037ff58349273e750c2f5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# $Id$
# Maintainer: Jan de Groot <jgc@archlinux.org>
pkgname=gstreamer0.10
pkgver=0.10.36
pkgrel=4
pkgdesc="GStreamer Multimedia Framework"
arch=('i686' 'x86_64')
license=('LGPL')
url="http://gstreamer.com"
depends=('libxml2' 'glib2')
makedepends=('intltool' 'pkgconfig' 'gobject-introspection' 'git')
source=("git://anongit.freedesktop.org/gstreamer-sdk/gstreamer#commit=3ddc31eaa18c3be1613e43430eca78a3e445639e"
tests-remove-silly-test_fail_abstract_new-check.patch
bison3.patch)
sha256sums=('SKIP'
'd3d3f4f04453831fdb4244bfe174a38c4e6f9f4da5c8c9050dcfa1a6097aad52'
'ed154e280abf59b24d98a8ab0fe868b449b26aa61f7ae3813fab8ac615fcaefa')
prepare() {
cd gstreamer
patch -Np1 -i ../tests-remove-silly-test_fail_abstract_new-check.patch
patch -Np1 -i ../bison3.patch
sed -e 's/AM_CONFIG_HEADER/AC_CONFIG_HEADERS/' -i configure.ac
}
build() {
cd gstreamer
NOCONFIGURE=1 ./autogen.sh
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --libexecdir=/usr/lib \
--with-package-name="GStreamer (Archlinux)" \
--with-package-origin="http://www.archlinux.org/" \
--disable-gtk-doc --disable-static
make
}
check() {
cd gstreamer
make check
}
package() {
cd gstreamer
make DESTDIR="${pkgdir}" install
#Remove unversioned gst-* binaries to get rid of conflicts
cd "${pkgdir}/usr/bin"
for bins in `ls *-0.10`; do
rm -f ${bins/-0.10/}
done
}
|
