blob: 9c989164ebea9cfb2a41cc0d986c8cc28adec6a9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# $Id: PKGBUILD 163770 2012-07-19 15:53:24Z andyrtr $
# Maintainer: Andreas Radke <andyrtr@archlinux.org>
pkgname=cups-filters
pkgver=1.0.19
pkgrel=1
pkgdesc="OpenPrinting CUPS Filters"
arch=('i686' 'x86_64')
url="http://www.linuxfoundation.org/collaborate/workgroups/openprinting"
license=('GPL')
depends=('lcms2' 'poppler>=0.20.1')
makedepends=('ghostscript' 'ttf-dejavu') # ttf-dejavu for make check
optdepends=('ghostscript: for non-PostScript printers to print with CUPS to convert PostScript to raster images'
'foomatic-db: drivers use Ghostscript to convert PostScript to a printable form directly'
'foomatic-db-engine: drivers use Ghostscript to convert PostScript to a printable form directly'
'foomatic-db-nonfree: drivers use Ghostscript to convert PostScript to a printable form directly')
backup=(etc/fonts/conf.d/99pdftoopvp.conf)
options=(!libtool)
source=(http://www.openprinting.org/download/cups-filters/$pkgname-$pkgver.tar.gz
buildfix_poppler.diff
buildfix_dlopen.diff)
md5sums=('e3c9ad58ec005eda2f0ac2f3190a63b3'
'b3d5b60a50568d06d1ef43c285ce7802'
'8b0c8874ef5c985287cada55db75d8d1')
build() {
cd "$srcdir/$pkgname-$pkgver"
# https://bugs.linuxfoundation.org/show_bug.cgi?id=1055
patch -Np0 -i ${srcdir}/buildfix_poppler.diff
patch -Np0 -i ${srcdir}/buildfix_dlopen.diff
autoreconf -v
./configure --prefix=/usr \
--sysconfdir=/etc \
--with-test-font-path=/usr/share/fonts/TTF/DejaVuSans.ttf
make
}
check() {
cd "$srcdir/$pkgname-$pkgver"
make -k check
}
package() {
cd "$srcdir/$pkgname-$pkgver"
make DESTDIR="$pkgdir/" install
# drop static lib
rm -f ${pkgdir}/usr/lib/*.a
}
|
