blob: 7bcfa95d9de3a80cebf545690613e87af76a4275 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# $Id$
# Maintainer: Alexander Rødseth <rodseth@gmail.com>
# Contriutor: Eric Belanger <eric@archlinux.org>
# Contributor: Jo Christian Bergskås <jcberg@gmail.com>
pkgname=fceux
pkgver=2.2.2
pkgrel=3
url='http://www.fceux.com/'
pkgdesc='Fast and ultra-compatible NES/Famicom emulator'
arch=('x86_64' 'i686')
license=('GPL')
depends=('sdl' 'gtk2' 'gd' 'desktop-file-utils' 'lua51' 'libgl' 'shared-mime-info')
makedepends=('scons' 'mesa-libgl' 'glu')
install='fceux.install'
source=("https://downloads.sourceforge.net/project/fceultra/Source%20Code/$pkgver%20src/$pkgname-$pkgver.src.tar.gz")
sha256sums=('804d11bdb4a195f3a580ce5d2d01be877582763378637e16186a22459f5fe5e1')
build() {
cd "$pkgname-$pkgver"
scons
}
package() {
cd "$pkgname-$pkgver"
scons install -i --prefix="$pkgdir/usr"
# scons install creates usr/share/pixmaps as a regular file, wtf?
rm -f "$pkgdir/usr/share/pixmaps"
install -d "$pkgdir/usr/share/doc/$pkgname"
cp -r documentation/* "$pkgdir/usr/share/doc/$pkgname/"
install -Dm644 changelog.txt "$pkgdir/usr/share/doc/$pkgname/"
# desktop shortcut
install -Dm644 "$pkgname.desktop" \
"$pkgdir/usr/share/applications/$pkgname.desktop"
install -Dm644 "$pkgname.png" \
"$pkgdir/usr/share/pixmaps/$pkgname.png"
}
# vim:set ts=2 sw=2 et:
|
