blob: 4988f095c9b5d72b5279d62901191075aaa31e77 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# $Id$
pkgname=gd
pkgver=2.1.1
pkgrel=3
pkgdesc="Library for the dynamic creation of images by programmers"
arch=('i686' 'x86_64')
url="http://www.libgd.org/"
license=('custom')
depends=('fontconfig' 'libvpx' 'libxpm' 'libtiff')
makedepends=('git')
optdepends=('perl: bdftogd script')
source=("${pkgname}::git+https://github.com/libgd/libgd.git#tag=${pkgname}-${pkgver}"
gd-2.1.1-libvpx-1.4.0.patch)
md5sums=('SKIP'
'9114dd8259aaa88b0a09188fe7b19afc')
prepare() {
cd ${pkgname}
./bootstrap.sh
patch -p1 -i "${srcdir}/gd-2.1.1-libvpx-1.4.0.patch"
}
build() {
cd ${pkgname}
./configure \
--prefix=/usr \
--disable-rpath \
--with-vpx=/usr \
--with-tiff=/usr
make
}
check() {
cd ${pkgname}
make check
}
package() {
cd ${pkgname}
make DESTDIR="${pkgdir}" install
install -D -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|
