blob: e0aadc8bdda9738966750d759bb9a7b66f4b91a2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Maintainer: Det <nimetonmaili at gmail a-dot com>
# Contributors: t3ddy, Lex Rivera aka x-demon, ruario
# Check for new Linux releases in: http://googlechromereleases.blogspot.com/search/label/Stable%20updates
# or use: $ curl -s https://dl.google.com/linux/chrome/rpm/stable/x86_64/repodata/other.xml.gz | gzip -df | awk -F\" '/pkgid/{ sub(".*-","",$4); print $4": "$10 }'
pkgname=google-chrome
pkgver=31.0.1650.48
pkgrel=1
pkgdesc="An attempt at creating a safer, faster, and more stable browser (Stable Channel)"
arch=('i686' 'x86_64')
url="https://www.google.com/chrome"
license=('custom:chrome')
depends=('alsa-lib' 'gconf' 'gtk2' 'hicolor-icon-theme' 'libpng' 'libxslt' 'libxss' 'nss' 'ttf-font' 'xdg-utils')
optdepends=('kdebase-kdialog: needed for file dialogs in KDE'
'ttf-google-fonts-git')
provides=("google-chrome=$pkgver")
conflicts=('google-chrome')
replaces=('chromium')
options=('!emptydirs' '!strip')
install=$pkgname.install
_channel=stable
_arch=i386
[ "$CARCH" = 'x86_64' ] && _arch=amd64
source=("google-chrome-${_channel}_${pkgver}_${_arch}.deb::https://dl.google.com/linux/direct/google-chrome-${_channel}_current_${_arch}.deb"
'https://www.google.com/intl/en/chrome/browser/privacy/eula_text.html')
md5sums=('2927095d2011c0ff771e5289d73aa240'
'6d57da7476a4b1b7a81821d9c036425c')
[ "$CARCH" = 'x86_64' ] && md5sums[0]='2927095d2011c0ff771e5289d73aa240'
#PKGEXT='.pkg.tar'
package() {
msg2 "Extracting the data.tar.lzma"
bsdtar -xf data.tar.lzma -C "$pkgdir/"
msg2 "Moving stuff in place"
# Desktop
mv "$pkgdir"/opt/google/chrome/google-chrome.desktop "$pkgdir"/usr/share/applications/
# Icons
for i in 16 22 24 32 48 64 128 256; do
install -Dm644 "$pkgdir"/opt/google/chrome/product_logo_${i}.png "$pkgdir"/usr/share/icons/hicolor/${i}x${i}/apps/google-chrome.png
done
# Man page
gzip "$pkgdir"/usr/share/man/man1/google-chrome.1
# License
install -Dm644 eula_text.html "$pkgdir"/usr/share/licenses/google-chrome/eula_text.html
msg2 "Symlinking missing Udev lib"
ln -s /usr/lib/libudev.so.1 "$pkgdir"/opt/google/chrome/libudev.so.0
msg2 "Removing the Debian-intended cron job and duplicated images"
rm -r "$pkgdir"/etc/cron.daily/ "$pkgdir"/opt/google/chrome/cron/
rm "$pkgdir"/opt/google/chrome/product_logo_*.png
}
|
