blob: 83716e57ffbc4bde2a92cdaee8ff7e54754e0308 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
|
# $Id$
# Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
# Contributor: Tobias Powalowski <tpowa@archlinux.org>
# Contributor: Hokum <hokum_at_mail_dot_ru>
pkgname=gptfdisk
pkgver=0.8.10
pkgrel=1
pkgdesc="A text-mode partitioning tool that works on GUID Partition Table (GPT) disks"
arch=('i686' 'x86_64')
url="http://www.rodsbooks.com/gdisk/"
license=('GPL2')
depends=('gcc-libs' 'util-linux' 'popt')
provides=("gdisk=$pkgver")
conflicts=('gdisk')
replaces=('gdisk')
source=(http://downloads.sourceforge.net/project/$pkgname/$pkgname/$pkgver/$pkgname-$pkgver.tar.gz)
sha256sums=('73e64151203ae0c347c488358e71ca582bb7fb7f0d66df86b71c42050390eb9b')
build() {
cd "$srcdir/$pkgname-$pkgver"
make
}
package () {
cd "$srcdir/$pkgname-$pkgver"
install -d "$pkgdir"/usr/{bin,share/{doc/gdisk,man/man8}}
install -t "$pkgdir/usr/bin" {,c,s}gdisk fixparts
install -m644 -t "$pkgdir/usr/share/man/man8" {{,c,s}gdisk,fixparts}.8
install -m644 -t "$pkgdir/usr/share/doc/gdisk" README NEWS
}
|
