blob: 0ee8e348bb01906ff88ae963ca1d69aa8e4a29d9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# $Id$
# Maintainer: Gaetan Bisson <bisson@archlinux.org>
# Contributor: kevin <kevin@archlinux.org>
# Contributor: John Proctor <jproctor@prium.net>
pkgname=graphviz
pkgver=2.38.0
pkgrel=3
pkgdesc='Graph visualization software'
url='http://www.graphviz.org/'
license=('CPL')
arch=('i686' 'x86_64')
depends=('libltdl' 'gd' 'librsvg' 'libxaw' 'ghostscript' 'pango' 'gts')
makedepends=('swig' 'mono' 'guile' 'lua51' 'ocaml' 'perl' 'php' 'python2' 'r' 'tk' 'qt4' 'gtk2')
optdepends=('mono: sharp bindings'
'guile: guile bindings'
'lua51: lua bindings'
'ocaml: ocaml bindings'
'perl: perl bindings'
'php: php bindings'
'python2: python bindings'
'r: r bindings'
'tcl: tcl bindings'
'qt4: gvedit'
'gtk2: gtk output plugin')
source=("${url}/pub/${pkgname}/stable/SOURCES/${pkgname}-${pkgver}.tar.gz"
'format-string.patch')
sha1sums=('053c771278909160916ca5464a0a98ebf034c6ef'
'271d116bc022596a64b6ee061f3d2e50fa2e6025')
install=install
prepare() {
cd "${srcdir}/${pkgname}-${pkgver}"
patch -p1 -i ../format-string.patch # FS#42983
}
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
export LIBPOSTFIX=/
export PYTHON=python2
export LUA=lua5.1
./configure --prefix=/usr
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
# Workaround symlink upgrade bug (fixed in pacman trunk)
# Also deduplicates the tcl libraries (upstream bug?)
# Might have been this commit: https://github.com/ellson/graphviz/commit/f11aead
rm -r "${pkgdir}/usr/lib/tcl8.6/graphviz"
ln -s ../graphviz/tcl "$pkgdir/usr/lib/tcl8.6/graphviz"
}
|
