summaryrefslogtreecommitdiffstats
path: root/abs/extra/gtk-doc/PKGBUILD
blob: 6d710d35fad490fd667acfc9bfbd9d72c60f6f83 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
# Maintainer: Jan de Groot <jgc@archlinux.org>

pkgname=gtk-doc
pkgver=1.29
pkgrel=1
pkgdesc="Documentation tool for public library API"
url="https://www.gtk.org/gtk-doc/"
arch=(any)
license=(GPL FDL)
depends=(docbook-xsl docbook-xml source-highlight glib2-docs python-lxml
         python-pygments python-anytree)
makedepends=(dblatex git yelp-tools)
checkdepends=(bc gtk3 python-six)
optdepends=('dblatex: PDF support')
_commit=7db567e83fe5d2d0659560c6dfb25ee27b338140  # tags/GTK_DOC_1_29^0
source=("git+https://gitlab.gnome.org/GNOME/gtk-doc.git#commit=$_commit")
sha256sums=('SKIP')

pkgver() {
  cd $pkgname
  git describe --tags | sed -e 's/GTK_DOC_//' -e 's/_/\./g' -e 's/-/+/g'
}

prepare() {
  cd $pkgname
  NOCONFIGURE=1 ./autogen.sh
}

build() {
  cd $pkgname
  ./configure --prefix=/usr --disable-static
  make
}

check() {
  cd $pkgname
  make check
}

package() {
  cd $pkgname
  make DESTDIR="$pkgdir" install
}