blob: bd062d0cbeab23e03abe6719ac590f0a98e034d8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
|
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: Ionut Biru <ibiru@archlinux.org>
pkgbase=gtk3
pkgname=(gtk3 gtk-update-icon-cache)
pkgver=3.24.4+15+g80b5024239
pkgrel=1
pkgdesc="GObject-based multi-platform GUI toolkit"
arch=(x86_64)
url="https://www.gtk.org/"
depends=(atk cairo libxcursor libxinerama libxrandr libxi libepoxy gdk-pixbuf2 dconf
libxcomposite libxdamage pango shared-mime-info at-spi2-atk wayland libxkbcommon
adwaita-icon-theme json-glib librsvg wayland-protocols desktop-file-utils mesa
cantarell-fonts colord rest libcups libcanberra)
makedepends=(gobject-introspection gtk-doc git glib2-docs sassc)
license=(LGPL)
_commit=80b5024239ee358ede8203666dfe9ea790a29b70 # gtk-3-24
source=("git+https://gitlab.gnome.org/GNOME/gtk.git#commit=$_commit"
settings.ini
gtk-query-immodules-3.0.hook
gtk-update-icon-cache.hook
gtk-update-icon-cache.script)
sha256sums=('SKIP'
'01fc1d81dc82c4a052ac6e25bf9a04e7647267cc3017bc91f9ce3e63e5eb9202'
'de46e5514ff39a7a65e01e485e874775ab1c0ad20b8e94ada43f4a6af1370845'
'496064a9dd6214bd58f689dd817dbdc4d7f17d42a8c9940a87018c3f829ce308'
'f1d3a0dbfd82f7339301abecdbe5f024337919b48bd0e09296bb0e79863b2541')
pkgver() {
cd gtk
git describe --tags | sed 's/-/+/g'
}
prepare() {
cd gtk
NOCONFIGURE=1 ./autogen.sh
}
build() {
cd gtk
./configure --prefix=/usr \
--sysconfdir=/etc \
--localstatedir=/var \
--disable-schemas-compile \
--enable-x11-backend \
--enable-broadway-backend \
--enable-wayland-backend \
--disable-gtk-doc
#https://bugzilla.gnome.org/show_bug.cgi?id=655517
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
package_gtk3() {
depends+=(gtk-update-icon-cache)
provides=(gtk3-print-backends)
conflicts=(gtk3-print-backends)
replaces=("gtk3-print-backends<=3.22.26-1")
install=gtk3.install
DESTDIR="$pkgdir" make -C gtk install
install -Dt "$pkgdir/usr/share/gtk-3.0" -m644 settings.ini
install -Dt "$pkgdir/usr/share/libalpm/hooks" -m644 gtk-query-immodules-3.0.hook
# split this out to use with gtk2 too
mv "$pkgdir/usr/bin/gtk-update-icon-cache" "$srcdir"
}
package_gtk-update-icon-cache() {
pkgdesc="GTK+ icon cache updater"
depends=(gdk-pixbuf2 librsvg hicolor-icon-theme)
install -Dt "$pkgdir/usr/bin" gtk-update-icon-cache
install -Dt "$pkgdir/usr/share/libalpm/hooks" -m644 gtk-update-icon-cache.hook
install -D gtk-update-icon-cache.script "$pkgdir/usr/share/libalpm/scripts/gtk-update-icon-cache"
}
# vim:set ts=2 sw=2 et:
|
