blob: 7695503552579063fa993e4b4257207f236cf498 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# $Id: PKGBUILD 102962 2013-12-25 04:58:31Z bgyorgy $
# Maintainer: BlackEagle <ike DOT devolder AT gmail DOT com>
# Contributor: Bernhard Walle <bernhard.walle@gmx.de>
pkgname=lcdproc
pkgver=0.5.6
pkgrel=5
pkgdesc="Utility to drive one or more LCD (and LCD-like) devices"
arch=('i686' 'x86_64')
url="http://lcdproc.omnipotent.net/"
license=('GPL')
depends=('libftdi-compat' 'xosd')
optdepends=('perl: needed for some lcdproc tools')
backup=('etc/LCDd.conf'
'etc/lcdexec.conf'
'etc/lcdproc.conf'
'etc/lcdvc.conf')
source=("http://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver.tar.gz"
'lcdd.service')
sha256sums=('bd2f43c30ff43b30f43110abe6b4a5bc8e0267cb9f57fa97cc5e5ef9488b984a'
'0acdc0fb9668e6d5e023349874301153a16935e1ad757d550c426a9a7ac64638')
build() {
cd "$pkgname-$pkgver"
./configure \
--prefix=/usr \
--sbindir=/usr/bin \
--sysconfdir=/etc \
--enable-libusb \
--enable-lcdproc-menus \
--enable-stat-smbfs \
--enable-drivers=all
make
}
package() {
cd "$pkgname-$pkgver"
make DESTDIR="$pkgdir" install
sed -e "s/server\/drivers\//\/usr\/lib\/lcdproc\//g" -i "$pkgdir/etc/LCDd.conf"
install -Dm644 "$srcdir/lcdd.service" "$pkgdir/usr/lib/systemd/system/lcdd.service"
}
|
