blob: 9a41c989f081e4125ecd01675b51e0466bc382ff (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# $Id$
# Maintainer: Tobias Powalowski <tpowa@archlinux.org>
# Contributor: Christian Hesse <mail@eworm.de>
# Contributor: Marco A Rojas <marquicus at gmail dot com>
pkgname=ldb
pkgver=1.1.17
pkgrel=1
pkgdesc="A schema-less, ldap like, API and database"
arch=('i686' 'x86_64')
url="http://ldb.samba.org/"
source=(http://samba.org/ftp/${pkgname}/${pkgname}-${pkgver}.tar.gz)
license=('GPL3')
depends=('talloc' 'tevent' 'tdb' 'popt')
makedepends=('python2')
optdepends=('python2: for python bindings')
build() {
cd ${srcdir}/${pkgname}-${pkgver}
# change to use python2
sed -i -e "s|/usr/bin/env python$|/usr/bin/env python2|" buildtools/bin/waf
export PYTHON=/usr/bin/python2
./configure --prefix=/usr \
--disable-rpath \
--disable-rpath-install \
--bundled-libraries=NONE \
--builtin-libraries=replace \
--with-modulesdir=/usr/lib/ldb/modules \
--with-privatelibdir=/usr/lib/ldb
make
}
package() {
cd ${srcdir}/${pkgname}-${pkgver}
make DESTDIR=${pkgdir}/ install
}
md5sums=('7c2ab4e3f2a4186493aa06eabbc61cc0')
|
