blob: 9c6b59fb7d48ace8c02423d407f58071206aa02b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# $Id$
# Maintainer: Dave Reisner <dreisner@archlinux.org>
# Contributor: feydaykyn <feydaykyn@yahoo.fr>
pkgname=leveldb
pkgver=1.18
pkgrel=2
pkgdesc="A fast and lightweight key/value database library"
arch=('i686' 'x86_64')
url="https://code.google.com/p/leveldb/"
license=('BSD')
depends=('gperftools' 'snappy')
makedepends=('git')
source=("$pkgname-$pkgver.tar.gz::https://github.com/google/leveldb/archive/v$pkgver.tar.gz")
sha1sums=('18684a0ad7a07920d10f5295b171fbf5eeec7337')
build() {
make -C "$pkgname-$pkgver"
}
check() {
make -C "$pkgname-$pkgver" check
}
package() {
cd "$pkgname-$pkgver"
install -dm755 \
"$pkgdir"/usr/{include/leveldb,lib} \
"$pkgdir"/usr/share/doc/"$pkgname"
# libraries
install -m644 -t "$pkgdir/usr/lib" "libleveldb.so.${pkgver%.?*}" libleveldb.a
cp -P libleveldb.so* "$pkgdir/usr/lib"
# headers
install -m644 -t "$pkgdir/usr/include/leveldb" include/leveldb/*
# documentation
cp -r doc/* "$pkgdir/usr/share/doc/$pkgname"
# license
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|
