blob: 6fc979847b238332481a574f4e55c722f4186dcc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# $Id$
# Maintainer: Jan de Groot <jgc@archlinux.org>
pkgname=libproxy
pkgver=0.4.15
pkgrel=6
pkgdesc="A library that provides automatic proxy configuration management"
arch=(x86_64)
license=('LGPL')
depends=('gcc-libs')
optdepends=('perl: Perl bindings'
'python2: Python 2.x bindings'
'python: Python 3.x bindings'
'glib2: gsettings configuration module')
makedepends=('cmake' 'python' 'python2' 'perl')
url="http://libproxy.github.io/libproxy/"
source=(https://github.com/libproxy/libproxy/archive/${pkgver}.tar.gz)
sha256sums=('18f58b0a0043b6881774187427ead158d310127fc46a1c668ad6d207fb28b4e0')
prepare() {
if [ ! -d build ]; then
mkdir build
fi
}
build() {
cd build
cmake ../${pkgname}-${pkgver} \
-DCMAKE_INSTALL_PREFIX=/usr \
-DLIBEXEC_INSTALL_DIR=/usr/lib/libproxy \
-DCMAKE_SKIP_RPATH=ON \
-DPERL_VENDORINSTALL=yes \
-DCMAKE_BUILD_TYPE=Release \
-DWITH_WEBKIT3=OFF \
-DWITH_MOZJS=OFF \
-DCMAKE_CXX_FLAGS="${CXXFLAGS}" \
-DCMAKE_C_FLAGS="${CFLAGS}" \
-DPYTHON2_EXECUTABLE:FILEPATH=/usr/bin/python2 \
-DBIPR=0
make
}
package() {
cd build
make DESTDIR="${pkgdir}" install
}
|
