summaryrefslogtreecommitdiffstats
path: root/abs/extra/libsoxr/PKGBUILD
blob: b3b4a6ee91c44f8e9a0e271c20599fcb3cb975dc (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
# $Id$
# Maintainer: Anatol Pomozov
# Contributor: JSpaces <jspace -aT- unseen -d0T- is>
# Contributor: Triode <triode1 -aT- btinternet -d0t- com>

pkgname=libsoxr
pkgver=0.1.1
pkgrel=3
pkgdesc='The SoX Resampler library that aims to give fast and high quality results for any constant resampling ratio'
arch=(i686 x86_64) 
url='http://sourceforge.net/p/soxr/wiki/Home/'
license=(GPL)
depends=(gcc-libs)
makedepends=(cmake)
options=(!emptydirs)
source=(http://downloads.sourceforge.net/project/soxr/soxr-$pkgver-Source.tar.xz
        0001-fix-ineffectual-SOXR_MINIMUM_PHASE-and-SOXR_INTERMED.patch)
sha1sums=('f5d90e375db3914a522fef477898bde8c70243e7'
          '73e6a3418001ce01aa16c3d8e29e2535d0158111')

prepare() {
  cd soxr-$pkgver-Source
  patch -p1 < "$srcdir"/0001-fix-ineffectual-SOXR_MINIMUM_PHASE-and-SOXR_INTERMED.patch
}

build() {
  cd soxr-$pkgver-Source
  cmake \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DBUILD_EXAMPLES=OFF \
    -DBUILD_SHARED_LIBS=ON \
    -DCMAKE_BUILD_TYPE=Release \
    -DVISIBILITY_HIDDENL=ON \
    -DWITH_AVFFT=ON \
    -DWITH_DOUBLE_PRECISION=ON \
    -DWITH_LSR_BINDINGS=ON \
    -DWITH_OPENMP=ON \
    -DWITH_PFFFT=ON \
    -DWITH_SIMD=ON \
    .
  make
}

check() {
  cd soxr-$pkgver-Source
  make test
}

package() {
  cd soxr-$pkgver-Source
  
  make DESTDIR="$pkgdir" install
  install -Dm644 LICENCE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
  rm -r "$pkgdir"/usr/share/doc/$pkgname/
}