blob: 17af63a7ad9cd5b807b955972c56e72ed9eaffbe (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# $Id$
# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Ionut Biru <ibiru@archlinux.org>
# Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
pkgname=libvpx
pkgver=1.6.1
pkgrel=1
pkgdesc='VP8 and VP9 codec'
arch=('i686' 'x86_64')
url='http://www.webmproject.org/'
license=('BSD')
depends=('glibc' 'gcc-libs')
makedepends=('yasm' 'git')
provides=('libvpx.so')
source=("libvpx-${pkgver}.tar.gz::https://github.com/webmproject/libvpx/archive/v${pkgver}.tar.gz")
sha256sums=('cda8bb6f0e4848c018177d3a576fa83ed96d762554d7010fe4cfb9d70c22e588')
build() {
cd libvpx-${pkgver}
./configure \
--prefix='/usr' \
--enable-runtime-cpu-detect \
--enable-shared \
--enable-pic \
--disable-install-docs \
--disable-install-srcs \
--enable-vp8 \
--enable-postproc \
--enable-vp9 \
--enable-vp9-highbitdepth \
--enable-experimental \
--enable-spatial-svc
make
}
package() {
cd libvpx-${pkgver}
make DIST_DIR="${pkgdir}"/usr install
install -Dm 644 LICENSE -t "${pkgdir}"/usr/share/licenses/libvpx/
}
# vim: ts=2 sw=2 et:
|
