blob: bc91cadf67c804b570015dcf4319f09d643e5c81 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: Anatol Pomozov <anatol.pomozov@gmail.com>
# Contributor: Filip Brcic <brcha@gna.org>
# Contributor: Mika Fischer <mika.fischer@zoopnet.de>
# Contributor: Gergely Imreh <imrehgATgmailDOTcom>
pkgname=ninja
pkgver=1.9.0
pkgrel=1
pkgdesc='Small build system with a focus on speed'
arch=(x86_64)
url='https://ninja-build.org/'
license=(Apache)
depends=(gcc-libs)
makedepends=(python2 re2c emacs-nox)
source=($pkgname-$pkgver.zip::https://github.com/martine/ninja/archive/v$pkgver.zip)
sha1sums=('8dc0fe67796e1c50a00f9542af41021286977bde')
build() {
cd ninja-$pkgver
python2 configure.py --bootstrap
emacs -Q --batch -f batch-byte-compile misc/ninja-mode.el
}
check() {
cd ninja-$pkgver
python2 ./configure.py
./ninja ninja_test
}
package() {
cd ninja-$pkgver
install -m755 -D ninja "$pkgdir/usr/bin/ninja"
install -m644 -D doc/manual.asciidoc "$pkgdir/usr/share/doc/ninja/manual.asciidoc"
install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
install -m644 -D misc/ninja-mode.el "$pkgdir/usr/share/emacs/site-lisp/ninja-mode.el"
install -m644 -D misc/ninja-mode.elc "$pkgdir/usr/share/emacs/site-lisp/ninja-mode.elc"
install -m644 -D misc/ninja.vim "$pkgdir/usr/share/vim/vimfiles/syntax/ninja.vim"
install -m644 -D misc/bash-completion "$pkgdir/usr/share/bash-completion/completions/ninja"
install -m644 -D misc/zsh-completion "$pkgdir/usr/share/zsh/site-functions/_ninja"
}
|
