blob: 42c7df2d7169d1df835a894c7f5d80d1b4164be7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
# $Id$
# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Daniel Wallace <daniel.wallace@gatech.edu>
pkgname=plex-home-theater
pkgver=1.2.2
pkgrel=6
pkgdesc='Plex Home Theater'
arch=('i686' 'x86_64')
url='http://www.plexapp.com/'
license=('GPL2')
depends=('boost-libs' 'curl' 'ffmpeg-compat' 'glew' 'libcdio' 'libmad'
'libmicrohttpd' 'libmpeg2' 'libsamplerate' 'libssh' 'libusb-compat'
'libvdpau' 'libxrandr' 'lzo' 'sdl_image' 'sdl_mixer' 'smbclient'
'taglib' 'tinyxml' 'yajl')
makedepends=('boost' 'cmake' 'doxygen' 'java-environment' 'libcec' 'libplist'
'libshairport' 'nasm' 'swig' 'unzip' 'zip')
optdepends=('libplist: AirPlay support'
'libshairport: AirPlay support'
'libcec: Pulse-Eight USB-CEC adapter support'
'pulseaudio: PulseAudio support')
install="${pkgname}.install"
source=("https://github.com/plexinc/plex-home-theater-public/archive/pht-v${pkgver}.tar.gz"
'plex-ffmpeg-compat.patch'
'plex-libcec-2.2.0.patch'
'plex-lirc-socket.patch'
'plexhometheater.sh'
'plex_lib.conf')
prepare() {
cd plex-home-theater-public-pht-v${pkgver}
patch -Np1 -i ../plex-libcec-2.2.0.patch
patch -Np1 -i ../plex-lirc-socket.patch
patch -Np1 -i ../plex-ffmpeg-compat.patch
}
build() {
cd plex-home-theater-public-pht-v${pkgver}
if [[ -d build ]]; then
rm -rf build
fi
mkdir build && cd build
cmake .. -DCMAKE_INSTALL_PREFIX='/usr' \
-DCMAKE_C_FLAGS="$CMAKE_C_FLAGS -I/usr/include/glib-2.0 -I/usr/lib/glib-2.0/include" \
-DCMAKE_CXX_FLAGS="$CMAKE_CXX_FLAGS -I/usr/include/glib-2.0 -I/usr/lib/glib-2.0/include" \
-DENABLE_{AUTOUPDATE,DUMP_SYMBOLS}='FALSE' -DENABLE_PYTHON='TRUE' \
-DPYTHON_EXEC='/usr/bin/python2' -DUSE_INTERNAL_FFMPEG='FALSE' \
-DCREATE_BUNDLE='FALSE'
make
}
package() {
cd plex-home-theater-public-pht-v${pkgver}/build
make DESTDIR="${pkgdir}" install
install -dm 755 "${pkgdir}"/usr/{lib/plexhometheater,share/{applications,pixmaps}}
mv "${pkgdir}"/usr/bin/{system,xbmc-xrandr} "${pkgdir}"/usr/lib/plexhometheater/
mv "${pkgdir}"/usr/share/XBMC "${pkgdir}"/usr/share/plexhometheater
install -m 755 "${srcdir}"/plexhometheater.sh "${pkgdir}"/usr/bin/
install -m 644 ../plex/Resources/plexhometheater.desktop "${pkgdir}"/usr/share/applications/
install -m 644 ../plex/Resources/plex-icon-256.png "${pkgdir}"/usr/share/pixmaps/plexhometheater.png
# LinHES stuff
#add in plex_lib.conf
install -D -m0744 ${srcdir}/plex_lib.conf ${pkgdir}/etc/gen_lib_xml.d/plex_lib.conf
}
# vim: ts=2 sw=2 et:
md5sums=('10bc6dd7be91a33eba9b666c96f50a20'
'6704244166497db7fa6b3ddd43a0e53b'
'066484ad4949f96ddddaa8b1d4d709e1'
'b96a1d70174d80d3f2272bdc5b48e4a3'
'8fae1350cc36f40ed65fbf96128a02d0'
'8735a4e7857bc85085482c4f8bcb1d01')
|
