blob: 21b70bdf06c74d2614d98b4ffc6ecb1c3386adaa (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
|
# $Id$
# Maintainer : Tom Gundersen <teg@jklm.no>
# Maintainer : Ionut Biru <ibiru@archlinux.org>
pkgbase=transmission
pkgname=(transmission-cli transmission-gtk transmission-qt)
pkgver=2.93
pkgrel=1
arch=(x86_64)
url="http://www.transmissionbt.com/"
license=(MIT)
makedepends=(gtk3 intltool curl qt5-base libevent systemd qt5-tools)
source=(https://github.com/transmission/transmission-releases/raw/master/transmission-${pkgver}.tar.xz
transmission-2.90-libsystemd.patch
transmission-cli.sysusers
transmission-cli.tmpfiles)
sha256sums=('8815920e0a4499bcdadbbe89a4115092dab42ce5199f71ff9a926cfd12b9b90b'
'9f8f4bb532e0e46776dbd90e75557364f495ec95896ee35900ea222d69bda411'
'641310fb0590d40e00bea1b5b9c843953ab78edf019109f276be9c6a7bdaf5b2'
'1266032bb07e47d6bcdc7dabd74df2557cc466c33bf983a5881316a4cc098451')
prepare() {
cd $pkgbase-$pkgver
patch -p1 -i "$srcdir/transmission-2.90-libsystemd.patch"
rm -f m4/glib-gettext.m4
autoreconf -fi
sed -i '/^Icon=/ s/$/-qt/' qt/transmission-qt.desktop
}
build() {
cd $pkgbase-$pkgver
./configure --prefix=/usr
make
cd qt
qmake qtr.pro \
DEFINES+=TRANSLATIONS_DIR=\\\\\\\"/usr/share/transmission-qt/translations\\\\\\\"
make
lrelease translations/*.ts
}
package_transmission-cli() {
pkgdesc='Fast, easy, and free BitTorrent client (CLI tools, daemon and web client)'
depends=(curl libevent systemd)
cd $pkgbase-$pkgver
for dir in daemon cli web utils; do
make -C "$dir" DESTDIR="$pkgdir" install
done
install -Dm644 daemon/transmission-daemon.service \
"$pkgdir/usr/lib/systemd/system/transmission.service"
install -Dm644 COPYING "$pkgdir/usr/share/licenses/transmission-cli/COPYING"
install -Dm644 "$srcdir/$pkgname.sysusers" \
"$pkgdir/usr/lib/sysusers.d/transmission.conf"
install -Dm644 "$srcdir/$pkgname.tmpfiles" \
"$pkgdir/usr/lib/tmpfiles.d/transmission.conf"
}
package_transmission-gtk() {
pkgdesc='Fast, easy, and free BitTorrent client (GTK+ GUI)'
depends=(curl libevent gtk3 desktop-file-utils hicolor-icon-theme)
optdepends=('notification-daemon: Desktop notification support'
'transmission-cli: daemon and web support')
cd $pkgbase-$pkgver
make -C gtk DESTDIR="$pkgdir" install
make -C po DESTDIR="$pkgdir" install
install -Dm644 COPYING "$pkgdir/usr/share/licenses/transmission-gtk/COPYING"
}
package_transmission-qt() {
pkgdesc='Fast, easy, and free BitTorrent client (Qt GUI)'
depends=(curl qt5-base libevent)
optdepends=('transmission-cli: daemon and web support')
cd $pkgbase-$pkgver
make -C qt INSTALL_ROOT="$pkgdir"/usr install
install -Dm644 -t "$pkgdir/usr/share/transmission-qt/translations" \
qt/translations/*.qm
install -Dm644 COPYING "$pkgdir/usr/share/licenses/transmission-qt/COPYING"
install -Dm644 qt/icons/transmission.png \
"$pkgdir/usr/share/pixmaps/transmission-qt.png"
install -Dm644 qt/transmission-qt.desktop \
"$pkgdir/usr/share/applications/transmission-qt.desktop"
}
|
