blob: 1019be313bbd32db20f11bf52313f52851f119ac (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
# $Id: PKGBUILD 160601 2012-06-02 20:33:51Z ibiru $
# Maintainer: Ionut Biru <ibiru@archlinux.org>
pkgbase=vte3
pkgname=(vte3 vte-common)
pkgver=0.32.2
pkgrel=1
pkgdesc="Virtual Terminal Emulator widget for use with GTK3"
arch=('i686' 'x86_64')
license=('LGPL')
options=('!libtool' '!emptydirs')
makedepends=('intltool' 'gobject-introspection' 'gtk3')
url="http://www.gnome.org"
source=(http://ftp.gnome.org/pub/GNOME/sources/vte/${pkgver%.*}/vte-$pkgver.tar.xz)
sha256sums=('d69ec071f7a380d8b8b981b35a9a0b891f37c4b6b17d08407f66ac98d619486a')
build() {
cd "vte-$pkgver"
./configure --prefix=/usr --sysconfdir=/etc \
--libexecdir=/usr/lib/vte \
--localstatedir=/var --disable-static \
--enable-introspection
make
}
package_vte3(){
depends=('gtk3' 'vte-common')
cd "vte-$pkgver"
make DESTDIR="$pkgdir" install
rm "$pkgdir"/usr/lib/vte/gnome-pty-helper
}
package_vte-common() {
pkgdesc="Common files used by vte and vte3"
cd "vte-$pkgver"
make -C gnome-pty-helper DESTDIR="$pkgdir" install
}
|
