blob: 3d6b90e383fca0023b93067884d4369958732a4f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# $Id: PKGBUILD 94904 2010-10-12 06:47:49Z guillaume $
# Maintainer: Guillaume ALAUX <guillaume at alaux dot net>
# Contributor: Florian Pritz <bluewind at jabber dot ccc dot de>
pkgname=(wireshark-cli wireshark-gtk)
pkgbase=wireshark
pkgver=1.4.1
pkgrel=1
arch=('i686' 'x86_64')
license=('GPL2')
makedepends=('bison' 'flex' 'gtk2' 'heimdal' 'libpcap' 'bash' 'gnutls' 'libcap')
url="http://www.wireshark.org/"
options=(!libtool)
source=(http://www.wireshark.org/download/src/${pkgbase}-${pkgver}.tar.bz2)
md5sums=('1719d20a10990e7c2cb261df7021aab6')
build() {
cd "${srcdir}/${pkgbase}-${pkgver}"
export CFLAGS="-fno-unit-at-a-time ${CFLAGS}"
./configure --prefix=/usr --with-ssl
make all
}
package_wireshark-cli() {
pkgdesc="A free network protocol analyzer for Unix/Linux and Windows - CLI version"
depends=('heimdal' 'libpcap' 'bash' 'gnutls' 'libcap' 'glib2')
install=wireshark.install
conflicts=(wireshark)
cd "${srcdir}/${pkgbase}-${pkgver}"
make DESTDIR="${pkgdir}" install
#wireshark uid group is 150
chgrp 150 "${pkgdir}/usr/bin/dumpcap"
chmod 754 "${pkgdir}/usr/bin/dumpcap"
rm "$pkgdir/usr/bin/wireshark"
}
package_wireshark-gtk() {
pkgdesc="A free network protocol analyzer for Unix/Linux and Windows - GTK frontend"
depends=('gtk2' 'wireshark-cli')
install=wireshark-gtk.install
replaces=(wireshark)
conflicts=(wireshark)
cd "${srcdir}/${pkgbase}-${pkgver}"
install -Dm755 .libs/wireshark "$pkgdir/usr/bin/wireshark"
for d in 16 32 48; do
install -Dm644 image/hi${d}-app-wireshark.png ${pkgdir}/usr/share/icons/hicolor/${d}x${d}/apps/wireshark.png
done
install -Dm644 wireshark.desktop ${pkgdir}/usr/share/applications/wireshark.desktop
}
|
