blob: 87a9e78071c5bc5f3f852beb21d5704e113913dc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
|
# $Id$
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Brad Fanella <bradfanella@archlinux.us>
# Contributor: [vEX] <niechift.dot.vex.at.gmail.dot.com>
# Contributor: Zeqadious <zeqadious.at.gmail.dot.com>
# Contributor: BlackIkeEagle < ike DOT devolder AT gmail DOT com >
_prefix=/usr
pkgname=xbmc
pkgver=13.0
_codename=Gotham
pkgrel=2
pkgdesc="A software media player and entertainment hub for digital media"
arch=('i686' 'x86_64')
url="http://xbmc.org"
license=('GPL' 'custom')
depends=('hicolor-icon-theme' 'fribidi' 'lzo2' 'smbclient' 'libtiff' 'libva'
'libpng' 'libcdio' 'yajl' 'libmysqlclient' 'libjpeg-turbo' 'libsamplerate'
'glew' 'libssh' 'libmicrohttpd' 'libxrandr' 'sdl_mixer' 'sdl_image'
'python2' 'libass' 'libmpeg2' 'libmad' 'libmodplug' 'jasper' 'rtmpdump'
'unzip' 'mesa-demos' 'xorg-xdpyinfo' 'libbluray' 'libnfs' 'afpfs-ng'
'avahi' 'bluez-libs' 'tinyxml' 'libcap' 'swig' 'taglib'
'java-runtime-headless' 'glu' 'mesa' 'shairplay' 'libxslt' 'ffmpeg')
makedepends=('boost' 'cmake' 'gperf' 'nasm' 'libxinerama' 'zip' 'libvdpau' 'libcec'
'udisks' 'upower' 'mesa' 'doxygen' 'swig' 'java-environment')
optdepends=('libcec: support for Pulse-Eight USB-CEC adapter'
'lirc: remote controller support'
'udisks: automount external drives'
'upower: used to trigger power management functionality'
'unrar: access compressed files without unpacking them'
'xorg-xinit: autostart xbmc')
install="${pkgname}.install"
source=(
"xbmc-$pkgver.tar.gz::https://github.com/xbmc/xbmc/archive/13.0-Gotham.tar.gz"
"xbmc.service"
"polkit.rules"
"enable-external-ffmpeg.patch"
"xbmc.sh"
"xbmc_lib.conf"
)
prepare() {
cd "${srcdir}/xbmc-$pkgver-$_codename"
patch -p1 -i ../enable-external-ffmpeg.patch
}
build() {
cd "${srcdir}/xbmc-$pkgver-$_codename"
# Bootstrapping XBMC
./bootstrap
# Configuring XBMC
export PYTHON_VERSION=2 # external python v2
./configure --prefix=$_prefix --exec-prefix=$_prefix \
--disable-debug \
--enable-optimizations \
--enable-gl \
--enable-sdl \
--enable-vaapi \
--enable-vdpau \
--enable-xvba \
--enable-joystick \
--enable-xrandr \
--enable-rsxs \
--enable-projectm \
--enable-x11 \
--enable-rtmp \
--enable-samba \
--enable-nfs \
--enable-afpclient \
--enable-airplay \
--enable-airtunes \
--enable-ffmpeg-libvorbis \
--enable-dvdcss \
--disable-hal \
--enable-avahi \
--enable-webserver \
--enable-optical-drive \
--enable-libbluray \
--enable-texturepacker \
--enable-udev \
--enable-libusb \
--enable-libcec \
--enable-external-libraries
# Now (finally) build
make
}
package() {
cd "${srcdir}/xbmc-$pkgver-$_codename"
# Running make install
make DESTDIR="${pkgdir}" install
# run feh with python2
sed -i -e 's/python/python2/g' ${pkgdir}${_prefix}/bin/xbmc
# Tools
msg2 "Tools"
install -D -m 0755 "${srcdir}/xbmc-$pkgver-$_codename/xbmc-xrandr" "${pkgdir}${_prefix}/share/xbmc/xbmc-xrandr"
install -D -m 0755 "${srcdir}/xbmc-$pkgver-$_codename/tools/TexturePacker/TexturePacker" "${pkgdir}${_prefix}/share/xbmc/"
# Licenses
msg2 "Copy licenses"
install -dm755 ${pkgdir}${_prefix}/share/licenses/${pkgname}
for licensef in LICENSE.GPL copying.txt; do
mv ${pkgdir}${_prefix}/share/doc/xbmc/${licensef} \
${pkgdir}${_prefix}/share/licenses/${pkgname}
done
# LinHES stuff
mkdir -p ${pkgdir}/usr/LH/bin
install -D -m 0755 ${srcdir}/xbmc.sh ${pkgdir}/usr/LH/bin
#add in xbmc_lib.conf
install -D -m0744 ${srcdir}/xbmc_lib.conf ${pkgdir}/etc/gen_lib_xml.d/xbmc_lib.conf
# install systemd service
install -Dm0644 $srcdir/xbmc.service $pkgdir/usr/lib/systemd/system/xbmc.service
install -Dm0644 $srcdir/polkit.rules $pkgdir/etc/polkit-1/rules.d/10-xbmc.rules
}
md5sums=('54fafd985b5209859ba6faeb50b8f142'
'de331663cc8adc94f2fe44a262cfff58'
'02f7951824ee13103344f36009c0ef2a'
'9f9b41cfc1e21b1e7d0bb10d6e85b3c6'
'e48a3d87984669ef206e902bc8290ff9'
'71176cb0e5aaa230d7c9634c37245bfb')
|
