blob: b268acd6ba6e13b4a88b87431c47da29972d5c54 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
|
# shellcheck shell=bash
# shellcheck disable=SC2034 # Various variables that are used by makepkg
# shellcheck disable=SC2154 # Various variables that are provided by makepkg
# Maintainer: eomanis at web dot de
pkgname='certbot-dns-duckdns'
_pkgverUpstream="1.3"
pkgver="1.3.0"
pkgrel=1
pkgdesc="Plugin for certbot for a DNS-01 challenge with a DuckDNS domain"
arch=('any')
url='https://github.com/infinityofspace/certbot_dns_duckdns'
license=('MIT')
depends=('certbot' 'python-dnspython' 'python-requests')
makedepends=( 'python-build' 'python-installer' 'python-wheel' )
source=("https://github.com/infinityofspace/certbot_dns_duckdns/archive/refs/tags/v${_pkgverUpstream}.tar.gz")
sha256sums=('1faa4ebfb4902056dd90d45f8544a925d81ce8df34ab5d232acfb97e1bf12848')
build() {
local srcRootDir="${srcdir}/certbot_dns_duckdns-${_pkgverUpstream}"
cd "$srcRootDir" || return 1
python -m build --wheel --no-isolation
}
package() {
local srcRootDir="${srcdir}/certbot_dns_duckdns-${_pkgverUpstream}"
cd "$srcRootDir" || return 1
python -m installer --destdir="$pkgdir" dist/*.whl
}
|
