1 files changed, 52 insertions, 0 deletions
diff --git a/abs/core/python_modules/python-zope-interface/PKGBUILD b/abs/core/python_modules/python-zope-interface/PKGBUILD
new file mode 100644
index 0000000..c2e0df3
--- /dev/null
+++ b/abs/core/python_modules/python-zope-interface/PKGBUILD
@@ -0,0 +1,52 @@
+# $Id$
+# Maintainer : Felix Yan <felixonmars@archlinux.org>
+# Contributor: Ionut Biru <ibiru@archlinux.org>
+# Contributor: Douglas Soares de Andrade <douglas@archlinux.org>
+
+pkgbase=python-zope-interface
+pkgname=('python-zope-interface' 'python2-zope-interface')
+pkgver=4.4.3
+pkgrel=1
+license=('ZPL')
+arch=('x86_64')
+url="http://pypi.python.org/pypi/zope.interface"
+makedepends=('python-setuptools' 'python2-setuptools')
+checkdepends=('python-zope-event' 'python2-zope-event')
+source=("https://pypi.io/packages/source/z/zope.interface/zope.interface-$pkgver.tar.gz")
+sha512sums=('29d9f3f1fe9af8a4ffb1e6d2f067bba1fa1bac7b02690ba8429985aa6ca76d3f337076bc8c48f39d0f338ccd855800b2f28b319a183a285191cc007bf8d9c9ad')
+
+prepare() {
+  cp -a zope.interface-${pkgver}{,-py2}
+}
+
+build() {
+  cd "$srcdir"/zope.interface-$pkgver
+  python setup.py build
+
+  cd "$srcdir"/zope.interface-$pkgver-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/zope.interface-$pkgver
+  python setup.py test
+
+  cd "$srcdir"/zope.interface-$pkgver-py2
+  python2 setup.py test
+}
+
+package_python-zope-interface() {
+  pkgdesc='Zope Interfaces for Python 3.x'
+  depends=('python')
+ 
+  cd zope.interface-$pkgver
+  python setup.py install --prefix=/usr --root="$pkgdir" --optimize=1
+}
+
+package_python2-zope-interface(){
+  pkgdesc='Zope Interfaces for Python 2.x'
+  depends=('python2')
+
+  cd zope.interface-$pkgver-py2
+  python2 setup.py install --prefix=/usr --root="$pkgdir" --optimize=1
+}