1 files changed, 39 insertions, 0 deletions
diff --git a/abs/extra/intel-gmmlib/PKGBUILD b/abs/extra/intel-gmmlib/PKGBUILD
new file mode 100644
index 0000000..eaa609d
--- /dev/null
+++ b/abs/extra/intel-gmmlib/PKGBUILD
@@ -0,0 +1,39 @@
+# Maintainer: Bruno Pagani <archange@archlinux.org>
+# Contributor: Daniel Bermond < yahoo-com: danielbermond >
+
+pkgname=intel-gmmlib
+pkgver=19.1.1
+pkgrel=1
+pkgdesc="Intel Graphics Memory Management Library"
+arch=('x86_64')
+url="https://github.com/intel/gmmlib/"
+license=('MIT')
+depends=('gcc-libs')
+makedepends=('cmake')
+provides=('gmmlib')
+conflicts=('gmmlib')
+replaces=('gmmlib')
+options=('!emptydirs')
+source=("https://github.com/${pkgname/-//}/archive/${pkgname}-${pkgver}.tar.gz")
+sha256sums=('aab4241bde754225a84d71a459f5734c311a6437305ca7e99cd5cbeaab5ff6d5')
+
+prepare() {
+    mkdir -p build
+}
+
+build() {
+    cd build
+    cmake ../${pkgname#*-}-${pkgname}-${pkgver} \
+        -DCMAKE_BUILD_TYPE='None' \
+        -DCMAKE_INSTALL_PREFIX=/usr \
+        -DCMAKE_INSTALL_LIBDIR=lib \
+        -DRUN_TEST_SUITE=ON \
+        -Wno-dev
+    make
+}
+
+package() {
+    cd build
+    make DESTDIR="${pkgdir}" install
+    install -Dm644 ../${pkgname#*-}-${pkgname}-${pkgver}/LICENSE.md -t "${pkgdir}"/usr/share/licenses/${pkgname}/
+}