1 files changed, 29 insertions, 0 deletions
diff --git a/abs/extra/publicsuffix-list/PKGBUILD b/abs/extra/publicsuffix-list/PKGBUILD
new file mode 100644
index 0000000..6dfc4e4
--- /dev/null
+++ b/abs/extra/publicsuffix-list/PKGBUILD
@@ -0,0 +1,29 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+
+pkgname=publicsuffix-list
+_gitcommit=85fa8fbdf73a0f2fcf5f4790c204394557dfbaf3
+pkgver=20180223.632.85fa8fb
+pkgrel=1
+pkgdesc='Cross-vendor public domain suffix database'
+url='https://github.com/publicsuffix/list'
+arch=('any')
+license=('custom:MPL2')
+makedepends=('git')
+source=(${pkgname}::"git+https://github.com/publicsuffix/list#commit=${_gitcommit}")
+sha512sums=('SKIP')
+
+pkgver() {
+  cd ${pkgname}
+  printf "%s.%s.%s" "$(date +%Y%m%d --date="@${SOURCE_DATE_EPOCH:-$(date +%s)}")" \
+    "$(git rev-list --count HEAD)" \
+    "$(git rev-parse --short HEAD)"
+}
+
+package() {
+  cd ${pkgname}
+  install -Dm 644 public_suffix_list.dat tests/test_psl.txt -t "${pkgdir}/usr/share/publicsuffix"
+  ln -s public_suffix_list.dat "${pkgdir}/usr/share/publicsuffix/effective_tld_names.dat"
+  install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
+}
+
+# vim: ts=2 sw=2 et: